SolidWorksMakroprogrammierung

Methode · ModelDoc2

GetType-Methode (ModelDoc2)

Liefert, ob das Dokument ein Teil, eine Baugruppe oder eine Zeichnung ist.

Syntax

Function GetType() As Long
nTyp = swModel.GetType

Rückgabewert

Die Art des Dokuments als Wert aus swDocumentTypes_e. In Makros kommen praktisch nur drei Werte vor:

  • swDocPART (1): Teil (.sldprt)
  • swDocASSEMBLY (2): Baugruppe (.sldasm)
  • swDocDRAWING (3): Zeichnung (.slddrw)

Die übrigen Werte der Enumeration (swDocNONE, swDocSDM, swDocLAYOUT und die Multi-CAD-Werte swDocIMPORTED_PART und swDocIMPORTED_ASSEMBLY) fängst du mit Case Else ab.

Beispiel

' Zeigt die Namen aller Blätter der aktiven Zeichnung an.
' Vorbedingung: Eine Zeichnung ist geöffnet. Bei einem Teil oder einer
'               Baugruppe meldet das Makro, dass es nur für Zeichnungen ist.
' Ergebnis:     Meldung mit Anzahl und Namen der Blätter.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swDraw As SldWorks.DrawingDoc
    Dim vNamen As Variant

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc

    If swModel Is Nothing Then
        swApp.SendMsgToUser2 "Kein Dokument geöffnet.", swMbWarning, swMbOk
        Exit Sub
    End If
    If swModel.GetType <> swDocDRAWING Then
        swApp.SendMsgToUser2 "Dieses Makro funktioniert nur in Zeichnungen.", swMbStop, swMbOk
        Exit Sub
    End If

    Set swDraw = swModel
    vNamen = swDraw.GetSheetNames
    swApp.SendMsgToUser2 swDraw.GetSheetCount & " Blätter:" & vbCrLf & Join(vNamen, vbCrLf), swMbInformation, swMbOk
End Sub

Bemerkungen

SldWorks.ActiveDoc und die Befehle zum Öffnen liefern immer ein allgemeines ModelDoc2. Befehle, die es nur für Zeichnungen, Teile oder Baugruppen gibt, stehen erst zur Verfügung, wenn du dasselbe Dokument einer Variable vom passenden Typ zuweist: Set swDraw = swModel für DrawingDoc, Set swPart = swModel für PartDoc, Set swAssy = swModel für AssemblyDoc. Passt der Typ nicht, bricht VBA mit Laufzeitfehler 13 ab („Typen unverträglich“). Prüfe deshalb vorher mit GetType.

Vergleiche immer mit dem Namen der Konstante (swDocDRAWING), nicht mit der Zahl. Das liest sich besser und schützt vor Verwechslungen. Soll ein Makro je nach Dokumentart etwas anderes tun, ist Select Case swModel.GetType übersichtlicher als mehrere If. Ein Beispiel dafür steht bei SldWorks.ActiveDoc.

GetType funktioniert auch für die Bauteile einer Baugruppe. Das Dokument hinter einer Komponente liefert Component2.GetModelDoc2. Bei unterdrückten oder reduziert geladenen Komponenten (Lightweight) ist das Nothing. Prüfe das deshalb vorher:

Dim swCompModel As SldWorks.ModelDoc2
Set swCompModel = swComp.GetModelDoc2
If Not swCompModel Is Nothing Then
    If swCompModel.GetType = swDocASSEMBLY Then
        Debug.Print swComp.Name2 & " ist eine Unterbaugruppe"
    End If
End If

GetType braucht ein geöffnetes Dokument. Um die Art einer Datei zu erkennen, die nicht geöffnet ist, reicht meist die Dateiendung.

Siehe auch

In den Videos

In 15 Beiträgen verwendet. Alle in der Lösungssuche →

Verfügbarkeit

SOLIDWORKS 2001Plus

Englisches Original: IModelDoc2::GetType in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.