SolidWorksMakroprogrammierung

Methode · Component2

GetModelDoc2-Methode (Component2)

Liefert das Modell hinter einer Komponente, also das Teil oder die Unterbaugruppe als ModelDoc2.

Syntax

Function GetModelDoc2() As Object
Set swCompModel = swComp.GetModelDoc2

Rückgabewert

Das ModelDoc2 der Komponente, oder Nothing, wenn das Modell nicht geladen ist.

Beispiel

' Listet für jede Komponente die Dateieigenschaft "Benennung" ihres Modells.
' Vorbedingung: Eine Baugruppe ist geöffnet. Die Teile haben die Eigenschaft "Benennung".
' Ergebnis:     Liste im Direktfenster (Strg+G im VBA-Editor).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swAssy As SldWorks.AssemblyDoc
    Dim swComp As SldWorks.Component2
    Dim swCompModel As SldWorks.ModelDoc2
    Dim vKomponenten As Variant
    Dim sWert As String, sErgebnis As String
    Dim bAusgewertet As Boolean, bVerknuepft As Boolean
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocASSEMBLY Then Exit Sub
    Set swAssy = swModel

    vKomponenten = swAssy.GetComponents(False)
    If IsEmpty(vKomponenten) Then Exit Sub

    For i = 0 To UBound(vKomponenten)
        Set swComp = vKomponenten(i)
        Set swCompModel = swComp.GetModelDoc2
        If swCompModel Is Nothing Then
            Debug.Print swComp.Name2 & ": nicht geladen"
        Else
            sErgebnis = ""
            swCompModel.Extension.CustomPropertyManager("").Get6 "Benennung", False, sWert, sErgebnis, bAusgewertet, bVerknuepft
            Debug.Print swComp.Name2 & ": " & sErgebnis
        End If
    Next i
End Sub

Bemerkungen

GetModelDoc2 liefert Nothing, wenn die Komponente unterdrückt oder reduziert geladen ist oder SOLIDWORKS sie nicht im Speicher hat. Prüf das Ergebnis deshalb immer, wie im Beispiel, oder frag vorher Component2.GetSuppression2.

Das Modell ist die Datei, nicht die Komponente in der Baugruppe. Darin siehst du nichts, was nur in der Baugruppe gilt, etwa Features auf Baugruppenebene. Es zeigt außerdem den zuletzt gespeicherten Zustand oder, wenn die Datei offen ist, den Zustand des offenen Dokuments.

Auch die Konfiguration ist die, in der das Modell zuletzt gespeichert wurde, nicht unbedingt die verbaute. Für Features und Eigenschaften einer anderen Konfiguration nennt die Hilfe diesen Weg: das Modell aktivieren und die Konfiguration mit ModelDoc2.ShowConfiguration2 anzeigen. Welche Konfiguration verbaut ist, sagt Component2.ReferencedConfiguration.

Folge 22 und das Beispiel „Unabhängig machen“ holen sich so das Modell jeder Komponente. Der Vorgänger GetModelDoc ist veraltet.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2009

Englisches Original: IComponent2::GetModelDoc2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.