SolidWorksMakroprogrammierung

Methode · Component2

GetSuppression2-Methode (Component2)

Liefert den Zustand einer Komponente: unterdrückt, reduziert oder aufgelöst.

Syntax

Function GetSuppression2() As Long
nZustand = swComp.GetSuppression2

Rückgabewert

Der Zustand als Wert aus swComponentSuppressionState_e, etwa swComponentSuppressed (0) für unterdrückt oder swComponentLightweight (1) für reduziert.

Beispiel

' Zählt, wie viele Komponenten unterdrückt, reduziert oder aufgelöst sind.
' Vorbedingung: Eine Baugruppe ist geöffnet.
' Ergebnis:     Meldung mit den drei Zahlen.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swAssy As SldWorks.AssemblyDoc
    Dim swComp As SldWorks.Component2
    Dim vKomponenten As Variant
    Dim nUnterdrueckt As Long, nReduziert As Long, nAufgeloest As Long
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocASSEMBLY Then Exit Sub
    Set swAssy = swModel

    vKomponenten = swAssy.GetComponents(False)
    If IsEmpty(vKomponenten) Then Exit Sub

    For i = 0 To UBound(vKomponenten)
        Set swComp = vKomponenten(i)
        Select Case swComp.GetSuppression2
            Case swComponentSuppressed
                nUnterdrueckt = nUnterdrueckt + 1
            Case swComponentLightweight, swComponentFullyLightweight
                nReduziert = nReduziert + 1
            Case swComponentResolved, swComponentFullyResolved
                nAufgeloest = nAufgeloest + 1
        End Select
    Next i

    swApp.SendMsgToUser2 nUnterdrueckt & " unterdrückt, " & nReduziert & " reduziert, " & _
                         nAufgeloest & " aufgelöst", swMbInformation, swMbOk
End Sub

Bemerkungen

Der Zustand ist wichtig, weil unterdrückte und reduzierte Komponenten nur einen kleinen Teil ihrer Daten mitbringen. Bei ihnen liefert zum Beispiel Component2.GetModelDoc2 unter Umständen Nothing.

Welche Werte GetSuppression2 tatsächlich zurückgibt, sagt die Hilfe nicht genau. Die Beschreibungen in swComponentSuppressionState_e sind fürs Setzen formuliert. Das Beispiel fasst deshalb „reduziert“ und „vollständig reduziert“ zusammen, ebenso „aufgelöst“ und „vollständig aufgelöst“.

Neu gegenüber dem veralteten GetSuppression ist der Wert swComponentInternalIdMismatch (5). Er meldet einen Fehler bei der internen ID. GetSuppression2 gibt es erst seit SOLIDWORKS 2019. Für ältere Versionen ist Component2.IsSuppressed eine einfache Alternative, die nur unterdrückt oder nicht unterscheidet.

Ändern lässt sich der Zustand mit Component2.SetSuppression2.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2019

Englisches Original: IComponent2::GetSuppression2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.