SolidWorksMakroprogrammierung

Eigenschaft · ModelDocExtension

CustomPropertyManager-Eigenschaft (ModelDocExtension)

Liefert den CustomPropertyManager, mit dem ein Makro die Dateieigenschaften liest, schreibt und löscht, für die ganze Datei oder für eine Konfiguration.

Syntax

Property CustomPropertyManager( _
   ByVal ConfigName As String _
) As CustomPropertyManager    ' nur lesen
Set swProps = swModel.Extension.CustomPropertyManager("")

Parameter

ConfigNameStringByVal
"" für die Eigenschaften der Datei, im Dialog „Dateieigenschaften“ die Registerkarte „Benutzerdefiniert“. Der Name einer Konfiguration für ihre eigenen Eigenschaften, Registerkarte „Konfigurationsspezifisch“.

Wert

Der CustomPropertyManager für die Datei oder die angegebene Konfiguration.

Beispiel

' Schreibt alle benutzerdefinierten Eigenschaften des aktiven Dokuments
' mit Wert ins Direktfenster.
' Vorbedingung: Ein Dokument mit Dateieigenschaften ist geöffnet.
' Ergebnis:     Liste im Direktfenster (Strg+G im VBA-Editor).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swProps As SldWorks.CustomPropertyManager
    Dim vNamen As Variant
    Dim sWert As String
    Dim sErgebnis As String
    Dim bAufgeloest As Boolean
    Dim bVerknuepft As Boolean
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    Set swProps = swModel.Extension.CustomPropertyManager("")
    vNamen = swProps.GetNames
    If IsEmpty(vNamen) Then
        Debug.Print "Keine Dateieigenschaften."
        Exit Sub
    End If

    For i = 0 To UBound(vNamen)
        swProps.Get6 vNamen(i), False, sWert, sErgebnis, bAufgeloest, bVerknuepft
        Debug.Print vNamen(i) & " = " & sErgebnis & "   (eingetragen: " & sWert & ")"
    Next i
End Sub

Bemerkungen

Dateieigenschaften gibt es an zwei Stellen: für die ganze Datei ("") und für jede Konfiguration einzeln. Welche Stelle eine Zeichnung oder Stückliste anzeigt, hängt von deren Einstellungen ab. Ein Makro muss deshalb wissen, wo die Eigenschaft steht.

Eine Eigenschaft hat zwei Werte: den eingetragenen Text, etwa "SW-Masse@Welle.SLDPRT", und das Ergebnis, etwa 1.25. CustomPropertyManager.Get6 liefert beides. Für die meisten Makros zählt das Ergebnis.

Hat das Dokument keine Eigenschaften, liefert CustomPropertyManager.GetNames statt eines Arrays einen leeren Variant. Prüfe das mit IsEmpty, sonst bricht UBound mit einem Laufzeitfehler ab.

Neue Eigenschaften legst du mit CustomPropertyManager.Add3 an, ein Beispiel steht bei ModelDoc2.Extension. Die älteren Befehle direkt auf ModelDoc2, etwa AddCustomInfo3 oder CustomInfo2, sind veraltet.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2007

Englisches Original: IModelDocExtension::CustomPropertyManager in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.