Methode · CustomPropertyManager
Add3-Methode (CustomPropertyManager)
Legt eine Dateieigenschaft an, oder überschreibt eine vorhandene, je nach Option.
Syntax
Function Add3( _
ByVal FieldName As String, _
ByVal FieldType As Long, _
ByVal FieldValue As String, _
ByVal OverwriteExisting As Long _
) As LongnErgebnis = swProps.Add3(FieldName, swCustomInfoText, FieldValue, swCustomPropertyReplaceValue)Parameter
FieldNameStringByVal- Der Name der Eigenschaft, zum Beispiel
"Benennung". FieldTypeLongByVal- Die Art des Werts, ein Wert aus
swCustomInfoType_e, meistswCustomInfoText. FieldValueStringByVal- Der Wert als Text. Auch Zahlen und Verknüpfungen wie
"SW-Masse@Welle.SLDPRT"übergibst du als Text. OverwriteExistingLongByValWas passiert, wenn es die Eigenschaft schon gibt, ein Wert aus
swCustomPropertyAddOption_e:swCustomPropertyOnlyIfNew(0): nichts, die vorhandene bleibtswCustomPropertyDeleteAndAdd(1): löschen und neu anlegenswCustomPropertyReplaceValue(2): nur den Wert ersetzen
Rückgabewert
Ein Ergebniscode aus swCustomInfoAddResult_e:
swCustomInfoAddResult_AddedOrChanged(0): angelegt oder geändertswCustomInfoAddResult_GenericFail(1): ging nichtswCustomInfoAddResult_MismatchAgainstExistingType(2): die vorhandene Eigenschaft hat einen anderen TypswCustomInfoAddResult_MismatchAgainstSpecifiedType(3): der Wert passt nicht zum angegebenen Typ
Beispiel
' Trägt den Windows-Benutzer und das heutige Datum in die Dateieigenschaften ein.
' Vorbedingung: Ein Dokument ist geöffnet.
' Ergebnis: "Bearbeiter" und "Bearbeitet am" stehen unter Datei › Eigenschaften.
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swProps As SldWorks.CustomPropertyManager
Dim nErgebnis As Long
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
Set swProps = swModel.Extension.CustomPropertyManager("")
nErgebnis = swProps.Add3("Bearbeiter", swCustomInfoText, Environ("USERNAME"), swCustomPropertyReplaceValue)
If nErgebnis <> swCustomInfoAddResult_AddedOrChanged Then
swApp.SendMsgToUser2 "Bearbeiter nicht eingetragen, Code " & nErgebnis, swMbWarning, swMbOk
End If
swProps.Add3 "Bearbeitet am", swCustomInfoText, Format(Date, "dd.mm.yyyy"), swCustomPropertyReplaceValue
swModel.SetSaveFlag
End SubBemerkungen
Für die meisten Makros ist swCustomPropertyReplaceValue die richtige Wahl: Gibt es die Eigenschaft noch nicht, wird sie angelegt, sonst bekommt sie den neuen Wert. Mit swCustomPropertyOnlyIfNew setzt du Vorgabewerte, ohne Einträge des Benutzers zu überschreiben.
Mit swCustomPropertyReplaceValue bleibt der Typ der vorhandenen Eigenschaft erhalten. Passt er nicht zum neuen, meldet Add3 swCustomInfoAddResult_MismatchAgainstExistingType. Soll der Typ wechseln, nimm swCustomPropertyDeleteAndAdd.
Das Beispiel speichert das Datum als Text in einem festen Format. Das ist unabhängig von den Windows-Einstellungen. Der Typ swCustomInfoDate ist auch möglich, die Hilfe sagt aber nicht, in welchem Format SOLIDWORKS den Text dann erwartet.
Add3 ändert das Dokument nur im Speicher. Gespeichert wird erst mit ModelDoc2.Save3. Damit SOLIDWORKS beim Schließen nachfragt, setzt das Beispiel ModelDoc2.SetSaveFlag.
Siehe auch
In den Videos
Verfügbarkeit
SOLIDWORKS 2014
Englisches Original: ICustomPropertyManager::Add3 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.