SolidWorksMakroprogrammierung

Methode · ModelDoc2

GetPathName-Methode (ModelDoc2)

Liefert den vollständigen Pfad der Datei mit Dateinamen und Endung, oder einen leeren Text, wenn das Dokument noch nie gespeichert wurde.

Syntax

Function GetPathName() As String
sPfad = swModel.GetPathName

Rückgabewert

Der vollständige Pfad, zum Beispiel C:\Konstruktion\Welle.SLDPRT. Bei einem neuen Dokument, das noch nie gespeichert wurde, ein leerer Text ("").

Beispiel

' Zerlegt den Pfad des aktiven Dokuments in Ordner, Dateiname und Endung.
' Vorbedingung: Ein Dokument ist geöffnet und wurde schon einmal gespeichert.
' Ergebnis:     Meldung mit den drei Teilen.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim sPfad As String
    Dim sOrdner As String
    Dim sName As String
    Dim sEndung As String

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    sPfad = swModel.GetPathName
    If sPfad = "" Then
        swApp.SendMsgToUser2 "Das Dokument wurde noch nie gespeichert.", swMbWarning, swMbOk
        Exit Sub
    End If

    sOrdner = Left(sPfad, InStrRev(sPfad, "\"))                    ' mit \ am Ende
    sName = Mid(sPfad, InStrRev(sPfad, "\") + 1)
    sEndung = LCase(Mid(sName, InStrRev(sName, ".") + 1))
    sName = Left(sName, InStrRev(sName, ".") - 1)                  ' ohne Endung

    swApp.SendMsgToUser2 "Ordner: " & sOrdner & vbCrLf & "Name: " & sName & vbCrLf & "Endung: " & sEndung, swMbInformation, swMbOk
End Sub

Bemerkungen

Mit dem Pfad baust du neue Dateinamen, zum Beispiel für ein PDF neben der Zeichnung: sOrdner & sName & ".pdf". So entsteht meist der Dateiname, den du an ModelDocExtension.SaveAs3 übergibst.

SOLIDWORKS speichert die Endung meist in Großbuchstaben (.SLDPRT). Vergleiche Endungen deshalb immer mit LCase oder UCase, sonst schlägt If sEndung = "sldprt" fehl.

Ein leerer Pfad bedeutet: Das Dokument gibt es noch nicht als Datei. ModelDoc2.Save3 funktioniert dann nicht, das Makro muss mit ModelDocExtension.SaveAs3 einen Namen vergeben. Den Titel in der Fensterleiste liefert ModelDoc2.GetTitle. Er eignet sich nicht, um eine Datei eindeutig zu erkennen.

Den Pfad der Bauteile einer Baugruppe liefert Component2.GetPathName.

Siehe auch

In den Videos

In 14 Beiträgen verwendet. Alle in der Lösungssuche →

Verfügbarkeit

SOLIDWORKS 2001Plus

Englisches Original: IModelDoc2::GetPathName in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.