SolidWorksMakroprogrammierung

Methode · FeatureManager

FeatureExtrusion3-Methode (FeatureManager)

Extrudiert die ausgewählte Skizze zu einem Körper, mit Tiefe, Richtung, Formschräge und Startbedingung.

Syntax

Function FeatureExtrusion3( _
   ByVal Sd As Boolean, _
   ByVal Flip As Boolean, _
   ByVal Dir As Boolean, _
   ByVal T1 As Long, _
   ByVal T2 As Long, _
   ByVal D1 As Double, _
   ByVal D2 As Double, _
   ByVal Dchk1 As Boolean, _
   ByVal Dchk2 As Boolean, _
   ByVal Ddir1 As Boolean, _
   ByVal Ddir2 As Boolean, _
   ByVal Dang1 As Double, _
   ByVal Dang2 As Double, _
   ByVal OffsetReverse1 As Boolean, _
   ByVal OffsetReverse2 As Boolean, _
   ByVal TranslateSurface1 As Boolean, _
   ByVal TranslateSurface2 As Boolean, _
   ByVal Merge As Boolean, _
   ByVal UseFeatScope As Boolean, _
   ByVal UseAutoSelect As Boolean, _
   ByVal T0 As Long, _
   ByVal StartOffset As Double, _
   ByVal FlipStartOffset As Boolean _
) As Feature
Set swFeat = swFeatMgr.FeatureExtrusion3(True, False, False, swEndCondBlind, swEndCondBlind, 0.02, 0, _
    False, False, False, False, 0, 0, False, False, False, False, True, True, True, swStartSketchPlane, 0, False)

Parameter

SdBooleanByVal
True: in eine Richtung. False: in zwei Richtungen, dann gelten auch die Werte für Richtung 2.
FlipBooleanByVal
True kehrt die Seite um, die weggeschnitten wird. Für eine normale Extrusion False.
DirBooleanByVal
True kehrt die Richtung um. Ohne Umkehren geht die Extrusion in Richtung der Normalen der Skizze.
T1LongByVal
Endbedingung in Richtung 1, ein Wert aus swEndConditions_e, meist swEndCondBlind (0) für eine feste Tiefe.
T2LongByVal
Endbedingung in Richtung 2. Nur bei zwei Richtungen von Bedeutung.
D1DoubleByVal
Tiefe in Richtung 1 in Metern, 20 mm sind 0.02. Bei swEndCondOffsetFromSurface der Abstand zur Fläche.
D2DoubleByVal
Tiefe in Richtung 2 in Metern. Bei einer Richtung 0.
Dchk1BooleanByVal
True: Formschräge in Richtung 1.
Dchk2BooleanByVal
True: Formschräge in Richtung 2.
Ddir1BooleanByVal
Nur mit Formschräge in Richtung 1: True nach innen, False nach außen.
Ddir2BooleanByVal
Nur mit Formschräge in Richtung 2: True nach innen, False nach außen.
Dang1DoubleByVal
Nur mit Formschräge: der Winkel in Richtung 1 im Bogenmaß, sonst 0.
Dang2DoubleByVal
Nur mit Formschräge: der Winkel in Richtung 2 im Bogenmaß, sonst 0.
OffsetReverse1BooleanByVal
Nur bei swEndCondOffsetFromSurface in Richtung 1: True versetzt das Ende von der Skizze weg, False zur Skizze hin.
OffsetReverse2BooleanByVal
Dasselbe für Richtung 2.
TranslateSurface1BooleanByVal
Nur bei swEndCondOffsetFromSurface in Richtung 1: True, wenn das Ende eine verschobene Kopie der Referenzfläche ist, False für einen echten Abstand.
TranslateSurface2BooleanByVal
Dasselbe für Richtung 2.
MergeBooleanByVal
True: das Ergebnis mit den vorhandenen Körpern verschmelzen. Meist True.
UseFeatScopeBooleanByVal
True: das Feature wirkt nur auf bestimmte Körper. False: auf alle.
UseAutoSelectBooleanByVal
True: SOLIDWORKS wählt die betroffenen Körper selbst. False: du wählst sie vorher aus, jeden mit der Markierung 8.
T0LongByVal
Wo die Extrusion beginnt, ein Wert aus swStartConditions_e, meist swStartSketchPlane (0) für die Skizzenebene.
StartOffsetDoubleByVal
Nur bei swStartOffset: der Abstand von der Skizzenebene in Metern, sonst 0.
FlipStartOffsetBooleanByVal
Nur bei swStartOffset: True kehrt die Richtung dieses Abstands um.

Rückgabewert

Das neue Feature, oder Nothing, wenn SOLIDWORKS die Extrusion nicht erzeugen konnte.

Beispiel

' Skizziert auf der vorderen Ebene ein Rechteck 80 x 50 mm und extrudiert es 20 mm.
' Vorbedingung: Ein neues, leeres Teil ist geöffnet (deutsche oder englische Vorlage).
' Ergebnis:     Ein Quader 80 x 50 x 20 mm und eine Meldung mit dem Namen des neuen Features.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSkMgr As SldWorks.SketchManager
    Dim swSkizze As SldWorks.Feature
    Dim swFeat As SldWorks.Feature
    Dim bErfolg As Boolean

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    bErfolg = swModel.Extension.SelectByID2("Ebene vorne", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
    If False = bErfolg Then bErfolg = swModel.Extension.SelectByID2("Front Plane", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
    If False = bErfolg Then Exit Sub

    ' Skizze zeichnen und als Feature merken
    Set swSkMgr = swModel.SketchManager
    swSkMgr.InsertSketch True
    swSkMgr.AddToDB = True
    swSkMgr.CreateCornerRectangle -0.04, 0.025, 0, 0.04, -0.025, 0
    swSkMgr.AddToDB = False
    Set swSkizze = swSkMgr.ActiveSketch
    swSkMgr.InsertSketch True

    ' Skizze auswählen und 20 mm in eine Richtung extrudieren
    swSkizze.Select2 False, 0
    Set swFeat = swModel.FeatureManager.FeatureExtrusion3(True, False, False, _
        swEndCondBlind, swEndCondBlind, 0.02, 0, _
        False, False, False, False, 0, 0, _
        False, False, False, False, _
        True, True, True, _
        swStartSketchPlane, 0, False)

    If swFeat Is Nothing Then
        swApp.SendMsgToUser2 "Die Extrusion ist fehlgeschlagen.", swMbWarning, swMbOk
    Else
        swApp.SendMsgToUser2 "Neues Feature: " & swFeat.Name, swMbInformation, swMbOk
    End If
End Sub

Bemerkungen

Vor dem Aufruf muss die Skizze ausgewählt sein. Das Beispiel merkt sich die Skizze beim Zeichnen über SketchManager.ActiveSketch und wählt sie nach dem Schließen mit Feature.Select2 aus. Das klappt unabhängig vom Namen der Skizze und auch dann, wenn zwischendurch etwas anderes ausgewählt wurde. Folge 34 extrudiert direkt nach dem Schließen der Skizze, ohne sie neu auszuwählen.

Die 23 Parameter lassen sich in Gruppen lesen:

  • Richtung: Sd, Flip, Dir
  • Ende und Tiefe: T1, T2, D1, D2
  • Formschräge: Dchk1, Dchk2, Ddir1, Ddir2, Dang1, Dang2
  • Abstand von einer Fläche: OffsetReverse1, OffsetReverse2, TranslateSurface1, TranslateSurface2
  • Körper: Merge, UseFeatScope, UseAutoSelect
  • Start: T0, StartOffset, FlipStartOffset

Für eine einfache Extrusion mit fester Tiefe kommt es nur auf Sd, T1 und D1 an. Die übrigen Werte übernimmst du wie im Beispiel.

Längen sind in Metern, unabhängig von den Einheiten des Dokuments. Winkel sind im Bogenmaß, auch die der Formschräge: 1° sind 0.0174532925199433.

Ohne Umkehren zeigt die Richtung entlang der Normalen der Skizze. Bei zwei Richtungen zeigt Richtung 2 immer genau entgegengesetzt. Soll das Ende auf eine Fläche oder Ebene bezogen sein, wählst du diese vorher mit der Markierung 1 aus, eine Referenz für den Start mit 32.

Der Vorgänger FeatureExtrusion2 ist veraltet. Für einen Schnitt gibt es FeatureManager.FeatureCut4.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2014

Englisches Original: IFeatureManager::FeatureExtrusion3 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.