SolidWorksMakroprogrammierung

Methode · FeatureManager

FeatureCut4-Methode (FeatureManager)

Erzeugt aus der ausgewählten Skizze einen linear ausgetragenen Schnitt, auch in Blechteilen und Baugruppen.

Syntax

Function FeatureCut4( _
   ByVal Sd As Boolean, _
   ByVal Flip As Boolean, _
   ByVal Dir As Boolean, _
   ByVal T1 As Long, _
   ByVal T2 As Long, _
   ByVal D1 As Double, _
   ByVal D2 As Double, _
   ByVal Dchk1 As Boolean, _
   ByVal Dchk2 As Boolean, _
   ByVal Ddir1 As Boolean, _
   ByVal Ddir2 As Boolean, _
   ByVal Dang1 As Double, _
   ByVal Dang2 As Double, _
   ByVal OffsetReverse1 As Boolean, _
   ByVal OffsetReverse2 As Boolean, _
   ByVal TranslateSurface1 As Boolean, _
   ByVal TranslateSurface2 As Boolean, _
   ByVal NormalCut As Boolean, _
   ByVal UseFeatScope As Boolean, _
   ByVal UseAutoSelect As Boolean, _
   ByVal AssemblyFeatureScope As Boolean, _
   ByVal AutoSelectComponents As Boolean, _
   ByVal PropagateFeatureToParts As Boolean, _
   ByVal T0 As Long, _
   ByVal StartOffset As Double, _
   ByVal FlipStartOffset As Boolean, _
   ByVal OptimizeGeometry As Boolean _
) As Feature
Set swFeat = swFeatMgr.FeatureCut4(False, False, False, swEndCondThroughAll, swEndCondThroughAll, 0, 0, _
        False, False, False, False, 0, 0, False, False, False, False, _
        False, False, True, True, True, False, swStartSketchPlane, 0, False, False)

Parameter

SdBooleanByVal
True: in eine Richtung. False: in zwei Richtungen, dann gelten auch die Werte für Richtung 2.
FlipBooleanByVal
True: das Material außerhalb des Profils entfernen statt innerhalb (Seite umkehren).
DirBooleanByVal
True kehrt Richtung 1 um (siehe Bemerkungen).
T1LongByVal
Endbedingung in Richtung 1, ein Wert aus swEndConditions_e, etwa swEndCondBlind (0) oder swEndCondThroughAll (1).
T2LongByVal
Endbedingung in Richtung 2.
D1DoubleByVal
Tiefe in Richtung 1 in Metern.
D2DoubleByVal
Tiefe in Richtung 2 in Metern.
Dchk1BooleanByVal
True: Formschräge in Richtung 1.
Dchk2BooleanByVal
True: Formschräge in Richtung 2.
Ddir1BooleanByVal
Nur mit Formschräge in Richtung 1: True nach innen, False nach außen.
Ddir2BooleanByVal
Nur mit Formschräge in Richtung 2: True nach innen, False nach außen.
Dang1DoubleByVal
Nur mit Formschräge: Winkel in Richtung 1 im Bogenmaß.
Dang2DoubleByVal
Nur mit Formschräge: Winkel in Richtung 2 im Bogenmaß.
OffsetReverse1BooleanByVal
Nur bei Abstand von einer Fläche in Richtung 1: True versetzt von der Skizze weg, False zur Skizze hin.
OffsetReverse2BooleanByVal
Dasselbe für Richtung 2.
TranslateSurface1BooleanByVal
Nur bei swEndCondOffsetFromSurface in Richtung 1: True, wenn das Ende eine verschobene Kopie der Referenzfläche ist, False für einen echten Abstand.
TranslateSurface2BooleanByVal
Dasselbe für Richtung 2.
NormalCutBooleanByVal
Nur in Blechteilen: True schneidet senkrecht zur Blechdicke. In anderen Teilen False.
UseFeatScopeBooleanByVal
True: der Schnitt wirkt nur auf bestimmte Körper oder Komponenten. False: auf alle.
UseAutoSelectBooleanByVal
True: SOLIDWORKS wählt die betroffenen Körper oder Komponenten selbst. False: du wählst sie vorher aus.
AssemblyFeatureScopeBooleanByVal
Nur in Baugruppen: True, wenn der Schnitt nur auf ausgewählte Komponenten wirkt.
AutoSelectComponentsBooleanByVal
Nur in Baugruppen: True wählt alle betroffenen Komponenten automatisch.
PropagateFeatureToPartsBooleanByVal
Nur in Baugruppen: True überträgt den Schnitt in die Teile der betroffenen Komponenten.
T0LongByVal
Wo der Schnitt beginnt, ein Wert aus swStartConditions_e, meist swStartSketchPlane (0).
StartOffsetDoubleByVal
Nur bei swStartOffset: Abstand von der Skizzenebene in Metern.
FlipStartOffsetBooleanByVal
Nur bei swStartOffset: True kehrt die Richtung dieses Abstands um.
OptimizeGeometryBooleanByVal
Nur in Blechteilen mit NormalCut = True: True optimiert den senkrechten Schnitt.

Rückgabewert

Das neue Schnitt-Feature, oder Nothing, wenn er nicht entstehen konnte.

Beispiel

' Skizziert auf der vorderen Ebene einen Kreis mit 10 mm Durchmesser und schneidet ihn in beide Richtungen durch alles.
' Vorbedingung: Ein Teil mit einem Körper, der die vordere Ebene schneidet, ist geöffnet
'               (etwa der Quader aus dem Beispiel bei FeatureExtrusion3).
' Ergebnis:     Ein Loch durch den Körper und eine Meldung mit dem Namen des Schnitts.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSkMgr As SldWorks.SketchManager
    Dim swSkizze As SldWorks.Feature
    Dim swFeat As SldWorks.Feature
    Dim bErfolg As Boolean

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    bErfolg = swModel.Extension.SelectByID2("Ebene vorne", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
    If False = bErfolg Then bErfolg = swModel.Extension.SelectByID2("Front Plane", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
    If False = bErfolg Then Exit Sub

    Set swSkMgr = swModel.SketchManager
    swSkMgr.InsertSketch True
    swSkMgr.AddToDB = True
    swSkMgr.CreateCircleByRadius 0, 0, 0, 0.005
    swSkMgr.AddToDB = False
    Set swSkizze = swSkMgr.ActiveSketch
    swSkMgr.InsertSketch True

    swSkizze.Select2 False, 0
    Set swFeat = swModel.FeatureManager.FeatureCut4(False, False, False, _
        swEndCondThroughAll, swEndCondThroughAll, 0, 0, _
        False, False, False, False, 0, 0, _
        False, False, False, False, _
        False, False, True, True, True, False, _
        swStartSketchPlane, 0, False, False)

    If swFeat Is Nothing Then
        swApp.SendMsgToUser2 "Der Schnitt ist fehlgeschlagen.", swMbWarning, swMbOk
    Else
        swApp.SendMsgToUser2 "Neues Feature: " & swFeat.Name, swMbInformation, swMbOk
    End If
End Sub

Bemerkungen

Ohne Umkehren geht ein Schnitt entgegen der Normalen der Skizze, eine Extrusion dagegen entlang der Normalen. Bei zwei Richtungen zeigt Richtung 2 immer genau entgegengesetzt. Das Beispiel schneidet deshalb in beide Richtungen, dann trifft es den Körper sicher.

Die 27 Parameter entsprechen bis TranslateSurface2 denen von FeatureManager.FeatureExtrusion3, dort sind sie in Gruppen erklärt. Statt Merge kommen hier NormalCut und OptimizeGeometry für Blech sowie drei Werte für Baugruppen-Features hinzu. In einem normalen Teil übernimmst du für diese die Werte aus dem Beispiel.

Ergibt der Schnitt mehrere Körper, kannst du über die API nicht festlegen, welche davon bleiben sollen. Längen sind in Metern, Winkel im Bogenmaß. Der Vorgänger FeatureCut3 ist veraltet.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2017

Englisches Original: IFeatureManager::FeatureCut4 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.