SolidWorksMakroprogrammierung

Eigenschaft · SketchManager

ActiveSketch-Eigenschaft (SketchManager)

Liefert die Skizze, die gerade zum Bearbeiten offen ist, oder Nothing, wenn keine offen ist.

Syntax

Property ActiveSketch As Sketch    ' nur lesen
Set swSketch = swModel.SketchManager.ActiveSketch

Wert

Die offene Sketch, oder Nothing, wenn keine Skizze zum Bearbeiten offen ist.

Beispiel

' Zeigt Name und Anzahl der Skizzenelemente der gerade offenen Skizze.
' Vorbedingung: In einem Teil ist eine Skizze zum Bearbeiten offen.
' Ergebnis:     Meldung mit Name und Anzahl.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSketch As SldWorks.Sketch
    Dim swFeat As SldWorks.Feature
    Dim vSegmente As Variant
    Dim nAnzahl As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    Set swSketch = swModel.SketchManager.ActiveSketch
    If swSketch Is Nothing Then
        swApp.SendMsgToUser2 "Es ist keine Skizze offen.", swMbWarning, swMbOk
        Exit Sub
    End If

    Set swFeat = swSketch                         ' dieselbe Skizze als Feature, für den Namen
    vSegmente = swSketch.GetSketchSegments
    If Not IsEmpty(vSegmente) Then nAnzahl = UBound(vSegmente) + 1

    swApp.SendMsgToUser2 swFeat.Name & ": " & nAnzahl & " Skizzenelemente", swMbInformation, swMbOk
End Sub

Bemerkungen

Mit ActiveSketch prüft ein Makro, ob es zeichnen kann. Ohne offene Skizze verhalten sich die Zeichenbefehle unterschiedlich: SketchManager.CreateLine zeichnet nichts und liefert Nothing, SketchManager.CreateCircleByRadius legt dagegen eine neue Skizze an.

Den Namen einer Skizze liefert nicht das Sketch-Objekt, sondern das Feature dahinter. Dazu weist du die Skizze einer Variable vom Typ Feature zu, wie im Beispiel.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2008

Englisches Original: ISketchManager::ActiveSketch in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.