SolidWorksMakroprogrammierung

Methode · SketchManager

CreateCircleByRadius-Methode (SketchManager)

Zeichnet einen Kreis über Mittelpunkt und Radius in der offenen Skizze.

Syntax

Function CreateCircleByRadius( _
   ByVal XC As Double, _
   ByVal YC As Double, _
   ByVal Zc As Double, _
   ByVal Radius As Double _
) As SketchSegment
Set swKreis = swSkMgr.CreateCircleByRadius(XC, YC, Zc, Radius)

Parameter

XCDoubleByVal
X des Mittelpunkts in Metern.
YCDoubleByVal
Y des Mittelpunkts in Metern.
ZcDoubleByVal
Z des Mittelpunkts in Metern, in einer 2D-Skizze 0.
RadiusDoubleByVal
Der Radius in Metern. Nicht der Durchmesser.

Rückgabewert

Der neue Kreis als SketchSegment.

Beispiel

' Zeichnet vier Kreise mit 8 mm Durchmesser auf einem Lochkreis mit 60 mm Durchmesser.
' Vorbedingung: In einem Teil ist eine Skizze zum Bearbeiten offen.
' Ergebnis:     Vier Kreise um den Ursprung.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSkMgr As SldWorks.SketchManager
    Dim dLochkreis As Double
    Dim dWinkel As Double
    Dim i As Long
    Const PI As Double = 3.14159265358979

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    Set swSkMgr = swModel.SketchManager
    If swSkMgr.ActiveSketch Is Nothing Then Exit Sub

    dLochkreis = 0.06 / 2                     ' Radius des Lochkreises in m
    swSkMgr.AddToDB = True
    For i = 0 To 3
        dWinkel = i * PI / 2                  ' 0°, 90°, 180°, 270°
        swSkMgr.CreateCircleByRadius dLochkreis * Cos(dWinkel), dLochkreis * Sin(dWinkel), 0, 0.004
    Next i
    swSkMgr.AddToDB = False
End Sub

Bemerkungen

Der letzte Wert ist der Radius, nicht der Durchmesser. Eine Bohrung mit 8 mm Durchmesser bekommt 0.004. Das ist eine häufige Fehlerquelle.

CreateCircleByRadius legt eine neue Skizze an, wenn keine offen ist. Auf welcher Ebene sie dann liegt, sagt die Hilfe nicht. Öffne die Skizze deshalb lieber selbst mit SketchManager.InsertSketch.

Der Vorgänger ModelDoc2.CreateCircleByRadius2 ist veraltet.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2008

Englisches Original: ISketchManager::CreateCircleByRadius in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.