SolidWorksMakroprogrammierung

Methode · CustomPropertyManager

GetType2-Methode (CustomPropertyManager)

Liefert den Typ einer Dateieigenschaft: Text, Datum, Zahl, Ja/Nein und so weiter.

Syntax

Function GetType2( _
   ByVal FieldName As String _
) As Long
nTyp = swProps.GetType2(FieldName)

Parameter

FieldNameStringByVal
Der Name der Eigenschaft.

Rückgabewert

Der Typ als Wert aus swCustomInfoType_e, zum Beispiel swCustomInfoText (30).

Beispiel

' Zeigt, welchen Typ die Dateieigenschaft "Gewicht" hat.
' Vorbedingung: Ein Dokument mit der Eigenschaft "Gewicht" ist geöffnet.
' Ergebnis:     Meldung mit dem Typ.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim sTyp As String

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    Select Case swModel.Extension.CustomPropertyManager("").GetType2("Gewicht")
        Case swCustomInfoText:    sTyp = "Text"
        Case swCustomInfoDate:    sTyp = "Datum"
        Case swCustomInfoNumber:  sTyp = "Ganze Zahl"
        Case swCustomInfoDouble:  sTyp = "Zahl mit Nachkommastellen"
        Case swCustomInfoYesOrNo: sTyp = "Ja oder Nein"
        Case swCustomInfoEquation: sTyp = "Gleichung"
        Case Else:                sTyp = "unbekannt oder nicht vorhanden"
    End Select

    swApp.SendMsgToUser2 "Typ von ""Gewicht"": " & sTyp, swMbInformation, swMbOk
End Sub

Bemerkungen

Den Typ brauchst du vor allem, bevor du einen Wert mit CustomPropertyManager.Set2 änderst: Passt der neue Wert nicht zum Typ, schlägt Set2 fehl.

Der Vorgänger GetType ist veraltet. Er heißt genauso wie ModelDoc2.GetType, hat damit aber nichts zu tun.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2007

Englisches Original: ICustomPropertyManager::GetType2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.