SolidWorksMakroprogrammierung

Methode · Body2

DraftBody2-Methode (Body2)

Gibt Flächen eines temporären Körpers eine Formschräge.

Syntax

Function DraftBody2( _
   ByVal NumOfFaces As Long, _
   ByVal FaceList As Variant, _
   ByVal EdgeList As Variant, _
   ByVal BasePoint As Object, _
   ByVal DraftAngle As Double, _
   ByVal Dir As Variant _
) As Boolean
bErfolg = swTemp.DraftBody2(1, (vFlaechen), (vKanten), swPunkt, 0.0349, dRichtung)

Parameter

NumOfFacesLongByVal
Anzahl der Flächen.
FaceListVariantByVal
Array mit den Flächen.
EdgeListVariantByVal
Array mit einer Kante je Fläche, an der die Schräge ansetzt.
BasePointObjectByVal
Der Basispunkt als MathPoint.
DraftAngleDoubleByVal
Der Winkel im Bogenmaß.
DirVariantByVal
Array mit drei Double-Werten X, Y, Z, die Zugrichtung.

Rückgabewert

True, wenn es geklappt hat, sonst False.

Beispiel

' swTemp ist ein temporärer Körper, etwa aus Modeler.CreateBodyFromBox3.
' swFlaeche ist eine Seitenfläche, swKante ihre untere Kante.
Dim swMathUtil As SldWorks.MathUtility
Dim swPunkt As SldWorks.MathPoint
Dim aFlaechen(0) As SldWorks.Face2, aKanten(0) As SldWorks.Edge
Dim vFlaechen As Variant, vKanten As Variant
Dim dPunkt(2) As Double, dRichtung(2) As Double
Set swMathUtil = Application.SldWorks.GetMathUtility
Set swPunkt = swMathUtil.CreatePoint(dPunkt)     ' Basispunkt im Ursprung
Set aFlaechen(0) = swFlaeche: vFlaechen = aFlaechen  ' typisierte Arrays, nicht Array(...)
Set aKanten(0) = swKante: vKanten = aKanten
dRichtung(2) = 1                                ' Zugrichtung Z
If False = swTemp.DraftBody2(1, (vFlaechen), (vKanten), swPunkt, 2 * 3.14159265358979 / 180, dRichtung) Then Debug.Print "Keine Schräge"

Bemerkungen

Der Befehl verändert den Körper.

Arrays aus SOLIDWORKS-Objekten übergibst du als typisiertes Array (etwa Dim a(0) As SldWorks.Face2), zugewiesen an eine Variant-Variable und in Klammern übergeben. Ein mit Array(...) gebautes Array nehmen die Befehle nicht an (etwa an ModelDocExtension.GetSectionProperties2 und Modeler.CheckInterference3).

Zugrichtung als Double-Array: In SOLIDWORKS 2024 lieferte DraftBody2 mit Array(0#, 0#, 1#) als Zugrichtung False, mit einem Double-Array True.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2006

Englisches Original: IBody2::DraftBody2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.