SolidWorksMakroprogrammierung

Methode · Modeler

CheckInterference3-Methode (Modeler)

Prüft, ob sich Zielkörper und Werkzeugkörper durchdringen, und liefert auf Wunsch die betroffenen Flächen und Körper.

Syntax

Function CheckInterference3( _
   ByVal TargetBodies As Variant, _
   ByVal ToolBodies As Variant, _
   ByVal Options As Long, _
   ByRef Body1InterferedFaceArray As Variant, _
   ByRef Body2InterferedFaceArray As Variant, _
   ByRef IntersectedBodyArray As Variant _
) As Boolean
bKollision = swModeler.CheckInterference3(vZiele, vWerkzeuge, swBodyInterference_ReturnInterferingObject, vFlaechen1, vFlaechen2, vKoerper)

Parameter

TargetBodiesVariantByVal
Array mit den Zielkörpern (Body2).
ToolBodiesVariantByVal
Array mit den Werkzeugkörpern (Body2).
OptionsLongByVal
Optionen aus swCheckInterferenceOption_e, addiert: swBodyInterference_IncludeCoincidentFaces (2) zählt auch Flächen, die sich nur berühren, swBodyInterference_ReturnInterferingObject (4) füllt die drei Arrays. swBodyInterference_OptionDefault (1) schaltet beides aus.
Body1InterferedFaceArrayVariantByRef · Rückgabe
Gibt die Flächen (Face2) des ersten Körpers zurück, die mit dem zweiten kollidieren.
Body2InterferedFaceArrayVariantByRef · Rückgabe
Gibt die Flächen (Face2) des zweiten Körpers zurück, die mit dem ersten kollidieren.
IntersectedBodyArrayVariantByRef · Rückgabe
Gibt die interferierenden Körper (Body2) zurück, siehe Bemerkungen.

Rückgabewert

True, wenn es eine Interferenz gibt, sonst False.

Beispiel

' swModeler ist der Modeler (SldWorks.GetModeler), swPart ein Teil (PartDoc) mit mindestens zwei Volumenkörpern.
Dim vKoerper As Variant, vFl1 As Variant, vFl2 As Variant, vSchnitt As Variant
Dim aK1(0) As SldWorks.Body2, aK2(0) As SldWorks.Body2, vK1 As Variant, vK2 As Variant
vKoerper = swPart.GetBodies2(swSolidBody, True)
Set aK1(0) = vKoerper(0): vK1 = aK1               ' typisierte Arrays, nicht Array(...)
Set aK2(0) = vKoerper(1): vK2 = aK2
If swModeler.CheckInterference3((vK1), (vK2), _
        swBodyInterference_ReturnInterferingObject, vFl1, vFl2, vSchnitt) Then
    If IsArray(vFl1) Then Debug.Print "Flächen am ersten Körper: " & UBound(vFl1) + 1
    If IsArray(vSchnitt) Then Debug.Print "Interferierende Körper: " & UBound(vSchnitt) + 1
Else
    Debug.Print "Keine Interferenz"
End If

Bemerkungen

Der Befehl prüft Körper in einem Teil. Das Hilfebeispiel „Check Interference Among Bodies“ nimmt die Körper aus zwei Körperordnern eines Schweißteils (BodyFolder.GetBodies) und prüft einmal mit swBodyInterference_ReturnInterferingObject + swBodyInterference_IncludeCoincidentFaces und einmal mit swBodyInterference_OptionDefault. Auch beim zweiten Aufruf liest es die Arrays aus, obwohl swCheckInterferenceOption_e angibt, dass sie dann nicht gefüllt werden. Prüf sie deshalb mit IsArray, wie oben.

Was IntersectedBodyArray genau enthält, sagt die Hilfe nicht, nur „interferierende Körper“. Gemeint sind die beteiligten Körper oder, wie der Name nahelegt, die Körper der Durchdringung. Die Hilfe spricht außerdem vom „ersten“ und „zweiten Körper“. Wie das bei mehreren Ziel- und Werkzeugkörpern gemeint ist, sagt sie nicht. Vermutlich gehören die Flächen in Body1InterferedFaceArray zu den Zielkörpern und die in Body2InterferedFaceArray zu den Werkzeugkörpern.

Zwei Körper aus verschiedenen Komponenten einer Baugruppe prüfst du mit Modeler.CheckInterferenceBetweenTwoBodies. Für die Interferenzprüfung einer ganzen Baugruppe nennt die Hilfe AssemblyDoc.ToolsCheckInterference2 und das Objekt InterferenceDetectionMgr.

Übergib Ziel- und Werkzeugkörper als typisierte Arrays wie im Beispiel. Mit Array(...) gebauten Arrays meldet der Befehl keine Durchdringung, auch wenn sich die Körper durchdringen.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2009

Englisches Original: IModeler::CheckInterference3 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.