SolidWorksMakroprogrammierung

Methode · ModelDocExtension

GetSectionProperties2-Methode (ModelDocExtension)

Berechnet Fläche, Schwerpunkt und Flächenträgheitsmomente einer ebenen Fläche oder Skizze.

Syntax

Function GetSectionProperties2( _
   ByVal Sections As Variant _
) As Variant
vErg = swModel.Extension.GetSectionProperties2(vFlaechen)

Parameter

SectionsVariantByVal
Array mit ebenen Flächen oder Skizzen. Leer, wenn schon passende Elemente ausgewählt sind.

Rückgabewert

Array mit 24 Werten in SI-Einheiten (m², m, m⁴):

  • (0) Status: 0 erfolgreich, 1 ungültige Eingabe, 2 Flächen nicht in einer oder parallelen Ebenen, 3 nicht berechenbar
  • (1) Fläche
  • (2) bis (4) Schwerpunkt X, Y, Z
  • (5) bis (10) Trägheitsmomente XX, YY, ZZ, -XY, -ZX, -YZ
  • (11) polares Moment im Schwerpunkt
  • (12) Winkel zwischen Hauptachse und Teilachse
  • (13), (14) Hauptträgheitsmomente Ix, Iy im Schwerpunkt
  • (15) bis (23) Richtungen der Hauptachsen X, Y, Z (je x, y, z)

Beispiel

' swModel ist das aktive Teil, eine ebene Fläche ist ausgewählt.
Dim swFace As SldWorks.Face2
Dim vErg As Variant
Dim aFlaechen(0) As SldWorks.Face2
Dim vFlaechen As Variant
Set swFace = swModel.SelectionManager.GetSelectedObject6(1, -1)
swModel.ClearSelection2 True
Set aFlaechen(0) = swFace
vFlaechen = aFlaechen                           ' typisiertes Array, nicht Array(swFace)
vErg = swModel.Extension.GetSectionProperties2((vFlaechen))
If vErg(0) = 0 Then
    Debug.Print "Fläche: " & vErg(1) * 1000000# & " mm²"
    Debug.Print "Ix: " & vErg(13) * 1E+12 & " mm⁴, Iy: " & vErg(14) * 1E+12 & " mm⁴"
End If

Bemerkungen

Der Befehl hebt die Auswahl auf. Übergibst du ein Array und ist dasselbe Objekt schon ausgewählt, kommt Status 1. Deshalb hebt das Beispiel die Auswahl vorher auf. Ausgewählte Elemente und übergebenes Array werden zusammengerechnet. Funktioniert auch mit Schnittflächen und mit Schraffuren in Schnittansichten.

Übergibst du Array(swFace), kommt Status 3; mit einem typisierten Array wie im Beispiel kommt Status 0 und die richtige Fläche.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2005

Englisches Original: IModelDocExtension::GetSectionProperties2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.