SolidWorksMakroprogrammierung

Methode · ModelDocExtension

CreateMassProperty2-Methode (ModelDocExtension)

Liefert ein MassProperty2-Objekt mit Masse, Volumen, Oberfläche und Schwerpunkt des Teils oder der Baugruppe.

Syntax

Function CreateMassProperty2() As Object
Set swMass = swModel.Extension.CreateMassProperty2

Rückgabewert

Ein MassProperty2-Objekt, oder Nothing, wenn sich für das Dokument keine Masseneigenschaften berechnen lassen, etwa bei einem Teil, das nur aus Flächenkörpern besteht.

Beispiel

' Zeigt Masse, Volumen, Oberfläche und Schwerpunkt des aktiven Teils oder der Baugruppe.
' Vorbedingung: Ein Teil mit Volumenkörper oder eine Baugruppe ist geöffnet.
' Ergebnis:     Meldung mit den Werten.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swMass As SldWorks.MassProperty2
    Dim vSchwerpunkt As Variant

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType = swDocDRAWING Then Exit Sub

    swModel.ClearSelection2 True                   ' sonst zählen nur die ausgewählten Körper
    Set swMass = swModel.Extension.CreateMassProperty2
    If swMass Is Nothing Then
        swApp.SendMsgToUser2 "Keine Masseneigenschaften verfügbar.", swMbWarning, swMbOk
        Exit Sub
    End If

    vSchwerpunkt = swMass.CenterOfMass               ' x, y, z in Metern
    swApp.SendMsgToUser2 "Masse: " & Format(swMass.Mass, "0.000") & " kg" & vbCrLf & _
                         "Volumen: " & Format(swMass.Volume * 1000000, "0.0") & " cm³" & vbCrLf & _
                         "Oberfläche: " & Format(swMass.SurfaceArea * 10000, "0.0") & " cm²" & vbCrLf & _
                         "Schwerpunkt X: " & Format(vSchwerpunkt(0) * 1000, "0.0") & " mm", swMbInformation, swMbOk
End Sub

Bemerkungen

Die Werte kommen in SI-Einheiten: Kilogramm, Kubikmeter, Quadratmeter, Meter. Darum rechnet das Beispiel Volumen und Oberfläche in cm³ und cm² um und den Schwerpunkt in mm. Mit MassProperty2.UseSystemUnits = False liefert das Objekt die Werte stattdessen in den Einheiten des Dokuments.

Sind beim Aufruf Körper (im Teil) oder Komponenten (in der Baugruppe) ausgewählt, berechnet das Objekt nur diese. Für das ganze Modell hebst du die Auswahl vorher auf, wie im Beispiel. Umgekehrt kannst du gezielt einzelne Körper auswählen, etwa mit ModelDocExtension.SelectByID2, und nur deren Werte abfragen.

Die Vorgänger ModelDocExtension.CreateMassProperty, ModelDocExtension.GetMassProperties und ModelDoc2.GetMassProperties sind veraltet.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2020

Englisches Original: IModelDocExtension::CreateMassProperty2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.