SolidWorksMakroprogrammierung

Methode · ModelDocExtension

SelectByID2-Methode (ModelDocExtension)

Wählt ein Objekt über seinen Namen und seine Art aus, zum Beispiel eine Ebene, eine Skizze oder ein Feature.

Syntax

Function SelectByID2( _
   ByVal Name As String, _
   ByVal Type As String, _
   ByVal X As Double, _
   ByVal Y As Double, _
   ByVal Z As Double, _
   ByVal Append As Boolean, _
   ByVal Mark As Long, _
   ByVal Callout As Callout, _
   ByVal SelectOption As Long _
) As Boolean
bErfolg = swModel.Extension.SelectByID2(Name, Type, X, Y, Z, Append, Mark, Nothing, SelectOption)

Parameter

NameStringByVal
Der Name des Objekts, genau so geschrieben wie im FeatureManager, mit gleicher Groß- und Kleinschreibung, zum Beispiel "Ebene vorne" oder "Skizze1". Für Flächen, Kanten und Ecken, die keinen Namen haben, ein leerer Text "".
TypeStringByVal

Die Art des Objekts als Text in Großbuchstaben, zum Beispiel:

  • "PLANE": Ebene
  • "SKETCH": Skizze
  • "BODYFEATURE": Feature wie eine Extrusion oder Verrundung
  • "COMPONENT": Komponente einer Baugruppe
  • "DIMENSION": Bemaßung
  • "FACE", "EDGE", "VERTEX": Fläche, Kante, Ecke

Alle Texte stehen in der englischen Hilfe bei swSelectType_e in der Spalte „SelectByID2 string“.

XDoubleByVal
Punkt, an dem ausgewählt wird, in Metern im Koordinatensystem des Modells. Bei Objekten mit Namen, etwa Features aus dem FeatureManager, genügt 0.
YDoubleByVal
Wie X.
ZDoubleByVal
Wie X.
AppendBooleanByVal
False hebt die bisherige Auswahl auf und wählt nur dieses Objekt aus. True fügt das Objekt zur Auswahl hinzu. Ist es schon ausgewählt, wird es bei True wieder abgewählt.
MarkLongByVal
Eine Markierung für Befehle, die mehrere Auswahlen in bestimmten Rollen brauchen, etwa Pfad und Profil eines Austragungs-Features. Sonst 0.
CalloutCalloutByVal
Fast immer Nothing.
SelectOptionLongByVal
Ein Wert aus swSelectOption_e: swSelectOptionDefault (0) für normales Auswählen, swSelectOptionExtensive (1) wie mit gedrückter Umschalttaste.

Rückgabewert

True, wenn das Objekt ausgewählt wurde, sonst False.

Beispiel

' Wählt die vordere Ebene aus und öffnet darauf eine Skizze.
' Funktioniert mit deutschen und englischen Vorlagen.
' Vorbedingung: Ein Teil ist geöffnet.
' Ergebnis:     Eine neue Skizze auf der vorderen Ebene ist zum Bearbeiten offen.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swExt As SldWorks.ModelDocExtension
    Dim bErfolg As Boolean

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    Set swExt = swModel.Extension

    bErfolg = swExt.SelectByID2("Ebene vorne", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
    If False = bErfolg Then
        bErfolg = swExt.SelectByID2("Front Plane", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
    End If
    If False = bErfolg Then
        swApp.SendMsgToUser2 "Vordere Ebene nicht gefunden.", swMbWarning, swMbOk
        Exit Sub
    End If

    swModel.SketchManager.InsertSketch True
End Sub

Bemerkungen

Die Namen hängen von der Sprache der Vorlage ab: In einem deutschen Teil heißt die Ebene „Ebene vorne“, in einem englischen „Front Plane“. Ein Makro für beide Sprachen probiert deshalb beide Namen, wie im Beispiel. Benennt der Benutzer ein Feature um, findet SelectByID2 es unter dem alten Namen nicht mehr.

In einer Baugruppe folgen auf den Namen, jeweils mit @ abgetrennt, die Komponente und die Baugruppe, zu denen das Objekt gehört. "Ebene1@Welle-1@Baugruppe1" ist zum Beispiel die Ebene1 der Komponente Welle-1 in Baugruppe1. Bemaßungen brauchen den vollständigen Namen mit Dokument: "D1@Skizze1@Welle.SLDPRT".

Flächen und Kanten über Koordinaten auszuwählen, ist unzuverlässig: SelectByID2 sucht entlang der Blickrichtung, und die hängt von der aktuellen Ansicht ab. Dreht der Benutzer das Modell, trifft das Makro womöglich eine andere Fläche. Zuverlässiger ist ModelDocExtension.SelectByRay, dort gibst du die Richtung selbst vor.

SelectByID2 funktioniert auch, während ein PropertyManager offen ist. Die Auswahlbefehle einzelner Objekte, etwa von Features oder Komponenten, haben damit Probleme. Das Dokument muss geöffnet und sichtbar sein.

Der Vorgänger ModelDoc2.SelectByID ist veraltet.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2005

Englisches Original: IModelDocExtension::SelectByID2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.