SolidWorksMakroprogrammierung

Methode · ModelDoc2

Parameter-Methode (ModelDoc2)

Liefert eine Bemaßung des Dokuments über ihren vollständigen Namen, zum Beispiel "D1@Skizze1".

Syntax

Function Parameter( _
   ByVal StringIn As String _
) As Object
Set swDim = swModel.Parameter("D1@Skizze1")

Parameter

StringInStringByVal
Der vollständige Name der Bemaßung: Name der Bemaßung, @, Name des Features, zum Beispiel "D1@Skizze1".

Rückgabewert

Die Bemaßung als Dimension, oder Nothing, wenn es keine Bemaßung mit diesem Namen gibt.

Beispiel

' Liest die Bemaßung D1@Skizze1, verdoppelt sie und baut das Teil neu auf.
' Vorbedingung: Ein Teil mit der Skizze "Skizze1" und der Bemaßung "D1" ist geöffnet.
' Ergebnis:     Die Bemaßung hat den doppelten Wert, das Teil ist neu aufgebaut.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swDim As SldWorks.Dimension
    Dim vWerte As Variant
    Dim dWert As Double

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    Set swDim = swModel.Parameter("D1@Skizze1")
    If swDim Is Nothing Then
        swApp.SendMsgToUser2 "Bemaßung D1@Skizze1 nicht gefunden.", swMbWarning, swMbOk
        Exit Sub
    End If

    vWerte = swDim.GetValue3(swThisConfiguration, Empty)     ' ein Wert pro Konfiguration
    dWert = vWerte(0)
    swDim.SetValue3 dWert * 2, swSetValue_InThisConfiguration, Empty
    swModel.EditRebuild3

    Debug.Print "Vorher: " & dWert & ", jetzt: " & dWert * 2
End Sub

Bemerkungen

Den vollständigen Namen einer Bemaßung siehst du in SOLIDWORKS, wenn du auf die Bemaßung klickst: Im PropertyManager steht er unter „Primärer Wert“, zum Beispiel D1@Skizze1. Die Namen hängen von der Sprache der Vorlage ab. In einem englischen Teil heißt dieselbe Skizze Sketch1. Gib wichtigen Bemaßungen deshalb eigene Namen wie Laenge@Skizze1, dann läuft das Makro auch auf anderen Rechnern.

Die Zeichen @, . und / in Namen von Teilen oder Features bereiten Probleme: Der Befehl findet die Bemaßung dann womöglich nicht. Kennst du das Feature schon, ist Feature.Parameter einfacher. Dort reicht der kurze Name "D1".

Dimension.GetValue3 und Dimension.SetValue3 arbeiten in der Einheit des Dokuments, also meist Millimeter. Nach einer Änderung muss das Modell neu aufgebaut werden, sonst siehst du die Änderung nicht. Dafür ist ModelDoc2.EditRebuild3 da.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2001Plus

Englisches Original: IModelDoc2::Parameter in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.