SolidWorksMakroprogrammierung

Methode · Dimension

GetValue3-Methode (Dimension)

Liefert den Wert einer Bemaßung in der Einheit des Dokuments, für eine, mehrere oder alle Konfigurationen.

Syntax

Function GetValue3( _
   ByVal WhichConfigurations As Long, _
   ByVal Config_names As Variant _
) As Variant
vWerte = swDim.GetValue3(swThisConfiguration, Empty)

Parameter

WhichConfigurationsLongByVal

Für welche Konfigurationen, ein Wert aus swInConfigurationOpts_e:

  • swThisConfiguration (1): nur die aktive
  • swAllConfiguration (2): alle
  • swSpecifyConfiguration (3): die in Config_names genannten
Config_namesVariantByVal
Nur bei swSpecifyConfiguration: der Name einer Konfiguration oder ein Array mit Namen. Sonst Empty.

Rückgabewert

Ein Array mit den Werten, einer pro Konfiguration. Bei swThisConfiguration steht der Wert in vWerte(0).

Beispiel

' Zeigt den Wert von D1@Skizze1 in jeder Konfiguration des Teils.
' Vorbedingung: Ein Teil mit der Bemaßung D1@Skizze1 und mehreren Konfigurationen ist geöffnet.
' Ergebnis:     Liste im Direktfenster (Strg+G im VBA-Editor).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swDim As SldWorks.Dimension
    Dim vNamen As Variant
    Dim vWerte As Variant
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    Set swDim = swModel.Parameter("D1@Skizze1")
    If swDim Is Nothing Then Exit Sub

    vNamen = swModel.GetConfigurationNames
    For i = 0 To UBound(vNamen)
        vWerte = swDim.GetValue3(swSpecifyConfiguration, vNamen(i))
        Debug.Print vNamen(i) & ": " & vWerte(0)
    Next i
End Sub

Bemerkungen

Das Ergebnis ist immer ein Array, auch wenn du nur eine Konfiguration abfragst. Vergiss das (0) nicht: vWerte(0) ist die Zahl, vWerte allein ist das Array.

Die Einheit ist die des Dokuments, bei Längen meist Millimeter, bei Winkeln meist Grad. Für Rechnungen unabhängig von den Einstellungen des Dokuments nimm Dimension.GetSystemValue3.

Mit swSpecifyConfiguration liest du den Wert einer Konfiguration, ohne mit ModelDoc2.ShowConfiguration2 auf sie umzuschalten. Das Beispiel fragt jede Konfiguration einzeln ab. So ist sicher, welcher Wert zu welchem Namen gehört.

Die Vorgänger GetValue2 und die Eigenschaft Value sind veraltet.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2004

Englisches Original: IDimension::GetValue3 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.