SolidWorksMakroprogrammierung

Objekt · SldWorks

JoinFeatureData-Objekt

Die Definition eines Features „Verbinden“: welche Komponenten einer Baugruppe zu einem Teil vereinigt werden, ob sie danach ausgeblendet werden und ob berührende Flächen verbunden werden.

Deklaration Dim x As SldWorks.JoinFeatureData · in der englischen .NET-Hilfe: IJoinFeatureData

Beschreibung

JoinFeatureData gibt Zugriff auf ein Feature „Verbinden“ (join). Es entsteht in einer Baugruppe: Du bearbeitest ein Teil im Kontext der Baugruppe und vereinigst andere Komponenten zu einem Feature in diesem Teil. Das Feature steht danach im FeatureManager unter dem bearbeiteten Teil. Die Befehle gibt es seit SOLIDWORKS 2005.

Zugriff

  • Feature.GetDefinition: bei einem Feature „Verbinden“ im Teil, das im Kontext der Baugruppe bearbeitet wurde (siehe Bemerkungen)

Angelegt wird das Feature mit AssemblyDoc.InsertJoin2, während das Zielteil mit AssemblyDoc.EditPart2 bearbeitet wird.

Beispiel

' Gibt für das ausgewählte Feature „Verbinden“ die Einstellungen und die Namen der
' verbundenen Komponenten aus.
' Vorbedingung: Eine Baugruppe ist offen. Im FeatureManager ist unter einer Komponente
'               ein Feature „Verbinden“ ausgewählt.
' Ergebnis:     Die Werte stehen im Direktfenster, die Baugruppe bleibt unverändert.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSelMgr As SldWorks.SelectionMgr
    Dim swSel As Object
    Dim swFeat As SldWorks.Feature
    Dim swDef As Object
    Dim swDaten As SldWorks.JoinFeatureData
    Dim swZielKomp As SldWorks.Component2
    Dim swKomp As SldWorks.Component2
    Dim vKomps As Variant
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocASSEMBLY Then Exit Sub
    Set swSelMgr = swModel.SelectionManager
    Set swSel = swSelMgr.GetSelectedObject6(1, -1)
    If Not TypeOf swSel Is SldWorks.Feature Then Exit Sub
    Set swFeat = swSel
    Set swDef = swFeat.GetDefinition
    If Not TypeOf swDef Is SldWorks.JoinFeatureData Then Exit Sub
    Set swDaten = swDef
    Set swZielKomp = swSelMgr.GetSelectedObjectsComponent4(1, -1)

    If False = swDaten.AccessSelections(swModel, swZielKomp) Then Exit Sub
    Debug.Print swFeat.Name & ": " & swDaten.GetJoinedPartsCount & " Komponente(n), ausblenden " & _
                swDaten.HideParts & ", Berührung verbinden " & swDaten.ForceSurfaceContact
    vKomps = swDaten.JoinedParts
    If IsArray(vKomps) Then
        For i = 0 To UBound(vKomps)
            Set swKomp = vKomps(i)
            Debug.Print "  " & swKomp.Name2
        Next i
    End If
    swDaten.ReleaseSelectionAccess
End Sub

Bemerkungen

Typname: Die Tabelle zu Feature.GetTypeName2 führt für das Feature „Verbinden“ keinen Typnamen; in SOLIDWORKS 2024 lieferte es Join (deutscher Name „Vereinigen1“). Das Beispiel oben prüft mit TypeOf, ob die Definition ein JoinFeatureData ist.

Hilfebeispiel: „Insert Join Feature“ öffnet die Baugruppe arm2.sldasm, legt mit AssemblyDoc.EditPart2 und AssemblyDoc.InsertNewPart2 ein neues Teil an, wählt fünf Komponenten aus und ruft AssemblyDoc.InsertJoin2 auf. Dann wählt es das Feature mit dem Namen Join1@Part1^arm2-1@arm2 und dem Typ BODYFEATURE aus, holt die Definition, ruft AccessSelections mit der Baugruppe und Nothing auf und gibt JoinFeatureData.GetJoinedPartsCount aus.

Baugruppe oder Teil: Die Seite zu JoinFeatureData.AccessSelections sagt: In einer Baugruppe übergibst du die Komponente, in der das Feature liegt. Das Hilfebeispiel übergibt dort trotzdem Nothing. In SOLIDWORKS 2024 lieferte AccessSelections in der Baugruppe mit Nothing jedoch False, mit der Komponente True. Das Beispiel oben übergibt deshalb die Komponente aus SelectionMgr.GetSelectedObjectsComponent4.

Ändern: Nach AccessSelections setzt du die Werte und rufst Feature.ModifyDefinition auf. Änderst du nichts, rufst du JoinFeatureData.ReleaseSelectionAccess auf. Für Einzelheiten verweist die Hilfe auf das Thema „Accessing Selections that Define Features“.

Achtung: JoinFeatureData.HideParts kann True liefern, obwohl die Komponenten sichtbar sind, und JoinFeatureData.ForceSurfaceContact liefert nach dem Setzen auf True weiter False. Setzt du eine der beiden Eigenschaften auf True, werden die Komponenten ausgeblendet.

Eigenschaften und Methoden

Eigenschaften 3, davon 3 beschrieben

NameBeschreibung
ForceSurfaceContactLiest oder setzt, ob das Feature „Verbinden“ berührende Flächen und Durchdringungen verbindet.
HidePartsLiest oder setzt, ob die ursprünglichen Komponenten nach dem Verbinden ausgeblendet werden.
JoinedPartsLiest oder setzt die Komponenten, die das Feature „Verbinden“ vereinigt.

Methoden 3, davon 3 beschrieben

NameBeschreibung
AccessSelectionsSetzt das Modell vor das Feature „Verbinden“ zurück, damit du die Auswahlen lesen und ändern kannst, die es festlegen.
GetJoinedPartsCountLiefert die Zahl der Komponenten, die das Feature „Verbinden“ vereinigt.
ReleaseSelectionAccessHebt den Rücksetz-Zustand nach AccessSelections wieder auf, wenn du das Feature „Verbinden“ nicht geändert hast.

Nicht aufgeführt sind 2 C++-Varianten (Namen mit I davor, zum Beispiel IGetJoinedParts). In VBA nimmst du immer den Befehl ohne I.

Siehe auch

Englisches Original: IJoinFeatureData in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.