SolidWorksMakroprogrammierung

Methode · Feature

GetTypeName2-Methode (Feature)

Liefert die Art eines Features als festen englischen Text, zum Beispiel "Extrusion", "Fillet" oder "ProfileFeature" für eine Skizze.

Syntax

Function GetTypeName2() As String
sTyp = swFeat.GetTypeName2

Rückgabewert

Die Art des Features als Text. Häufige Werte:

  • ProfileFeature: Skizze
  • Extrusion: extrudierter Aufsatz
  • Cut: extrudierter Schnitt
  • Revolution: rotierter Aufsatz
  • Fillet: Verrundung
  • Chamfer: Fase
  • HoleWzd: Bohrung aus dem Bohrungsassistenten
  • LPattern, CirPattern: lineares und kreisförmiges Muster
  • Shell: Wandung
  • RefPlane: Ebene
  • Reference: Komponente in einer Baugruppe

Die vollständige Liste steht in der englischen Hilfe bei IFeature::GetTypeName2.

Beispiel

' Schreibt alle Features mit einer deutschen Bezeichnung ihrer Art ins Direktfenster.
' Vorbedingung: Ein Teil ist geöffnet.
' Ergebnis:     Liste im Direktfenster (Strg+G im VBA-Editor).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swFeat As SldWorks.Feature
    Dim sArt As String

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    Set swFeat = swModel.FirstFeature
    Do While Not swFeat Is Nothing
        Select Case swFeat.GetTypeName2
            Case "ProfileFeature": sArt = "Skizze"
            Case "Extrusion":      sArt = "Aufsatz"
            Case "Cut":            sArt = "Schnitt"
            Case "Fillet":         sArt = "Verrundung"
            Case "RefPlane":       sArt = "Ebene"
            Case Else:             sArt = swFeat.GetTypeName2
        End Select
        Debug.Print swFeat.Name & "  –  " & sArt
        Set swFeat = swFeat.GetNextFeature
    Loop
End Sub

Bemerkungen

Der Typ ist in jeder Sprachversion gleich und ändert sich nicht, wenn der Benutzer ein Feature umbenennt. Er ist deshalb der sichere Weg, Features zu erkennen. Feature.Name taugt nur für die Anzeige.

Vergleiche den Text genau, mit Groß- und Kleinschreibung: "Extrusion", nicht "extrusion". Ein Tippfehler fällt nicht auf, das Makro findet dann einfach nichts.

Mit dem Typ weißt du auch, welches speziellere Objekt hinter einem Feature steckt. Die Liste der Hilfe nennt es zu jedem Typ, etwa ProfileFeature → Sketch. Du bekommst es über Feature.GetSpecificFeature2 oder die Definition über Feature.GetDefinition. Nur bei Instant3D-Features (Typ „ICE“) liefert Feature.GetTypeName den zugrunde liegenden Typ, für alle anderen Features ist GetTypeName2 der richtige Befehl.

Auch eine gewöhnliche Schnitt-Extrusion kann als „ICE“ gemeldet werden statt als „Cut“.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2008

Englisches Original: IFeature::GetTypeName2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.