Objekt · SldWorks
IndentFeatureData-Objekt
Die Definition eines Features „Einbuchtung“: Zielkörper, Bereiche des Werkzeugkörpers, Dicke, Abstand und ob geschnitten wird.
Beschreibung
IndentFeatureData gibt Zugriff auf ein Feature „Einbuchtung“ (Indent). Eine Einbuchtung prägt die Form eines Werkzeugkörpers in einen Zielkörper ein, mit einer Wand der angegebenen Dicke und einem Abstand zum Werkzeug, oder sie schneidet den Überschneidungsbereich aus dem Zielkörper. Die Befehle gibt es seit SOLIDWORKS 2016.
Zugriff
Feature.GetDefinition: bei einem Feature mit dem TypnamenPunch
Angelegt wird das Feature mit FeatureManager.InsertIndent.
Beispiel
' Gibt Zielkörper, Zahl der Werkzeugbereiche, Dicke und Abstand der ausgewählten
' Einbuchtung aus und erhöht die Dicke um 1 mm.
' Vorbedingung: Ein Teil mit einer Einbuchtung ist offen, das Feature ist im
' FeatureManager ausgewählt.
' Ergebnis: Die Werte stehen im Direktfenster, die Einbuchtung ist 1 mm dicker.
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swSel As Object
Dim swFeat As SldWorks.Feature
Dim swDaten As SldWorks.IndentFeatureData
Dim swZiel As SldWorks.Body2
Dim vBereiche As Variant
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
Set swSel = swModel.SelectionManager.GetSelectedObject6(1, -1)
If Not TypeOf swSel Is SldWorks.Feature Then Exit Sub
Set swFeat = swSel
If swFeat.GetTypeName2 <> "Punch" Then Exit Sub
Set swDaten = swFeat.GetDefinition
If False = swDaten.AccessSelections(swModel, Nothing) Then Exit Sub
Set swZiel = swDaten.TargetBody
If Not swZiel Is Nothing Then Debug.Print "Zielkörper: " & swZiel.Name
vBereiche = swDaten.ToolBodyRegion
If IsArray(vBereiche) Then Debug.Print "Werkzeugbereiche: " & UBound(vBereiche) + 1
Debug.Print "Körper des Werkzeugs: " & swDaten.GetBodiesCount
Debug.Print "Schneiden: " & swDaten.IsCut
Debug.Print "Dicke: " & swDaten.Thickness * 1000 & " mm, Abstand: " & swDaten.Clearance * 1000 & " mm"
If swDaten.IsCut Then
swDaten.ReleaseSelectionAccess ' beim Schneiden gibt es keine Dicke
Exit Sub
End If
swDaten.Thickness = swDaten.Thickness + 0.001
If False = swFeat.ModifyDefinition(swDaten, swModel, Nothing) Then swDaten.ReleaseSelectionAccess
End SubBemerkungen
Typname: Feature.GetTypeName2 liefert für eine Einbuchtung Punch, nicht Indent.
Anlegen: Vor FeatureManager.InsertIndent wählst du den Zielkörper mit der Markierung 1 und die Bereiche des Werkzeugkörpers mit 4 aus.
Ändern: Rufe erst IndentFeatureData.AccessSelections auf und übernimm Änderungen mit Feature.ModifyDefinition. Ohne Änderung hebst du den Zustand mit IndentFeatureData.ReleaseSelectionAccess auf.
Schneiden: Ist IndentFeatureData.IsCut True, gibt es keine Dicke, der Abstand gilt aber. IndentFeatureData.Thickness gilt nur für Volumenkörper.
Einheiten: Die Hilfe nennt sie für Dicke und Abstand nicht. Die Dicke ist in Meter (1 mm im Dialog ergab 0,001), der Abstand vermutlich ebenso. Das Hilfebeispiel legt eine Einbuchtung mit 0.01 an und ändert die Dicke auf 0.011.
Hilfebeispiel: Das Beispiel „Insert Indent Feature“ öffnet multi_inter.sldprt, wählt einen Körper und eine Fläche, legt mit InsertIndent eine Einbuchtung an, liest Zielkörper und Werkzeugbereiche und ändert die Dicke.
Ohne IndentFeatureData.AccessSelections liefern Thickness, Clearance und IsCut nur 0 bzw. False. IndentFeatureData.TargetBody liefert Nothing, wenn der Zielkörper im Dialog über eine Fläche gewählt wurde, und FeatureManager.InsertIndent ohne Schneiden lieferte Nothing.
Eigenschaften und Methoden
Eigenschaften 8, davon 8 beschrieben
| Name | Beschreibung |
|---|---|
| Clearance | Liest oder setzt den Abstand zwischen Zielkörper und Werkzeugkörper der Einbuchtung. |
| ClearanceDirection | Liest oder setzt, ob die Richtung des Abstands der Einbuchtung umgekehrt ist. |
| CutDirection | Liest oder setzt, ob die Seite des Schnitts der Einbuchtung umgedreht ist. |
| IsCut | Liest oder setzt, ob die Einbuchtung den Überschneidungsbereich aus dem Zielkörper entfernt. |
| SelectionState | Liest oder setzt, ob die gewählten Bereiche des Werkzeugkörpers behalten oder entfernt werden. |
| TargetBody | Liest oder setzt den Volumen- oder Flächenkörper, in den die Einbuchtung eingeprägt wird. |
| Thickness | Liest oder setzt die Dicke der Einbuchtung. |
| ToolBodyRegion | Liest oder setzt die Bereiche des Werkzeugkörpers der Einbuchtung: Flächen oder Eckpunkte. |
Methoden 3, davon 3 beschrieben
| Name | Beschreibung |
|---|---|
| AccessSelections | Setzt das Modell vor die Einbuchtung zurück, damit du die Auswahlen lesen und ändern kannst, die sie festlegen. |
| GetBodiesCount | Liefert die Zahl der Volumen- oder Flächenkörper in den Bereichen des Werkzeugkörpers. |
| ReleaseSelectionAccess | Hebt den Rücksetz-Zustand nach AccessSelections wieder auf, wenn du die Einbuchtung nicht geändert hast. |
Siehe auch
Englisches Original: IIndentFeatureData in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.