SolidWorksMakroprogrammierung

Methode · FeatureManager

GetFeatures-Methode (FeatureManager)

Liefert die Features eines Dokuments als Array, nur die oberste Ebene oder mit allen Unter-Features.

Syntax

Function GetFeatures( _
   ByVal ToplevelOnly As Boolean _
) As Variant
vFeatures = swFeatMgr.GetFeatures(True)

Parameter

ToplevelOnlyBooleanByVal
True: nur die Features der obersten Ebene im FeatureManager. False: auch alle Unter-Features, etwa die Skizzen unter den Extrusionen.

Rückgabewert

Ein Array mit den Features als Feature-Objekte.

Beispiel

' Listet die Namen aller Skizzen, auch der Skizzen unter Extrusionen und Schnitten.
' Vorbedingung: Ein Teil ist geöffnet.
' Ergebnis:     Liste im Direktfenster (Strg+G im VBA-Editor).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swFeat As SldWorks.Feature
    Dim vFeatures As Variant
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    vFeatures = swModel.FeatureManager.GetFeatures(False)
    If IsEmpty(vFeatures) Then Exit Sub

    For i = 0 To UBound(vFeatures)
        Set swFeat = vFeatures(i)
        If swFeat.GetTypeName2 = "ProfileFeature" Then Debug.Print swFeat.Name
    Next i
End Sub

Bemerkungen

Die Features kommen in beliebiger Reihenfolge. Das Array sagt also nichts darüber, welches Feature im Baum oben steht oder zu welchem Feature ein Unter-Feature gehört. Brauchst du die Reihenfolge, geh den Baum mit ModelDoc2.FirstFeature und Feature.GetNextFeature durch.

Features in den Komponenten einer Baugruppe liefert GetFeatures nicht.

Ob vor der Schleife ein IsEmpty-Test nötig ist, sagt die Hilfe nicht. Er schadet nicht und schützt vor einem Fehler bei UBound. Die Folgen 20, 29 und 30 holen sich mit GetFeatures(True) die Features der obersten Ebene.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 2006

Englisches Original: IFeatureManager::GetFeatures in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.