SolidWorksMakroprogrammierung

Methode · FeatureManager

FeatureRevolve2-Methode (FeatureManager)

Erzeugt ein rotiertes Feature: Aufsatz, Schnitt oder dünnwandig, in eine oder zwei Richtungen.

Syntax

Function FeatureRevolve2( _
   ByVal SingleDir As Boolean, _
   ByVal IsSolid As Boolean, _
   ByVal IsThin As Boolean, _
   ByVal IsCut As Boolean, _
   ByVal ReverseDir As Boolean, _
   ByVal BothDirectionUpToSameEntity As Boolean, _
   ByVal Dir1Type As Long, _
   ByVal Dir2Type As Long, _
   ByVal Dir1Angle As Double, _
   ByVal Dir2Angle As Double, _
   ByVal OffsetReverse1 As Boolean, _
   ByVal OffsetReverse2 As Boolean, _
   ByVal OffsetDistance1 As Double, _
   ByVal OffsetDistance2 As Double, _
   ByVal ThinType As Long, _
   ByVal ThinThickness1 As Double, _
   ByVal ThinThickness2 As Double, _
   ByVal Merge As Boolean, _
   ByVal UseFeatScope As Boolean, _
   ByVal UseAutoSelect As Boolean _
) As Feature
Set swFeat = swFeatMgr.FeatureRevolve2(True, True, False, False, False, False, swEndCondBlind, swEndCondBlind, _
        2 * PI, 0, False, False, 0, 0, swThinWallOneDirection, 0, 0, True, True, True)

Parameter

SingleDirBooleanByVal
True: in eine Richtung. False: in zwei Richtungen.
IsSolidBooleanByVal
True für einen Volumenkörper.
IsThinBooleanByVal
True für ein dünnwandiges Feature.
IsCutBooleanByVal
True für einen rotierten Schnitt.
ReverseDirBooleanByVal
True kehrt die Drehrichtung um. Gilt nicht bei swEndCondMidPlane.
BothDirectionUpToSameEntityBooleanByVal
Nur bei zwei Richtungen bis zu demselben Element (Eckpunkt, Fläche, Abstand von Fläche): True, wenn beide Richtungen am selben Element enden. Dann wählst du es nur einmal aus.
Dir1TypeLongByVal
Endbedingung in Richtung 1, ein Wert aus swEndConditions_e, meist swEndCondBlind (0) für einen Winkel.
Dir2TypeLongByVal
Endbedingung in Richtung 2. Gilt nicht bei swEndCondMidPlane in Richtung 1.
Dir1AngleDoubleByVal
Winkel in Richtung 1 im Bogenmaß, nur bei swEndCondBlind. Eine volle Drehung ist 2 * PI.
Dir2AngleDoubleByVal
Winkel in Richtung 2 im Bogenmaß, nur bei swEndCondBlind.
OffsetReverse1BooleanByVal
Nur bei swEndCondOffsetFromSurface in Richtung 1: True kehrt die Richtung des Abstands um.
OffsetReverse2BooleanByVal
Dasselbe für Richtung 2.
OffsetDistance1DoubleByVal
Nur bei swEndCondOffsetFromSurface: Abstand in Richtung 1 in Metern.
OffsetDistance2DoubleByVal
Dasselbe für Richtung 2.
ThinTypeLongByVal
Nur bei dünnwandigen Features: Art und Richtung der Wand, ein Wert aus swThinWallType_e.
ThinThickness1DoubleByVal
Wandstärke in Richtung 1 in Metern. Bei swThinWallMidPlane gilt je Seite die Hälfte.
ThinThickness2DoubleByVal
Wandstärke in Richtung 2, nur bei swThinWallTwoDirection.
MergeBooleanByVal
True: mit vorhandenen Körpern verschmelzen.
UseFeatScopeBooleanByVal
True: das Feature wirkt nur auf bestimmte Körper. False: auf alle.
UseAutoSelectBooleanByVal
True: SOLIDWORKS wählt die betroffenen Körper selbst.

Rückgabewert

Das neue Feature.

Beispiel

' Skizziert auf der vorderen Ebene ein Rechteck neben einer Mittellinie und rotiert es um 360°.
' Vorbedingung: Ein neues, leeres Teil ist geöffnet (deutsche oder englische Vorlage).
' Ergebnis:     Ein Ring mit 20 mm Innen- und 60 mm Außendurchmesser, 40 mm hoch.
Option Explicit

Sub main()
    Const PI As Double = 3.14159265358979
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSkMgr As SldWorks.SketchManager
    Dim swSkizze As SldWorks.Feature
    Dim swAchse As SldWorks.SketchSegment
    Dim swSelData As SldWorks.SelectData
    Dim swFeat As SldWorks.Feature
    Dim bErfolg As Boolean

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    bErfolg = swModel.Extension.SelectByID2("Ebene vorne", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
    If False = bErfolg Then bErfolg = swModel.Extension.SelectByID2("Front Plane", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
    If False = bErfolg Then Exit Sub

    ' Rechteck rechts der y-Achse und Mittellinie auf der y-Achse
    Set swSkMgr = swModel.SketchManager
    swSkMgr.InsertSketch True
    swSkMgr.AddToDB = True
    swSkMgr.CreateCornerRectangle 0.01, 0.02, 0, 0.03, -0.02, 0
    Set swAchse = swSkMgr.CreateCenterLine(0, -0.03, 0, 0, 0.03, 0)
    swSkMgr.AddToDB = False
    Set swSkizze = swSkMgr.ActiveSketch
    swSkMgr.InsertSketch True

    ' Skizze mit Markierung 0, Achse mit Markierung 4 auswählen
    swSkizze.Select2 False, 0
    Set swSelData = swModel.SelectionManager.CreateSelectData
    swSelData.Mark = 4
    swAchse.Select4 True, swSelData

    Set swFeat = swModel.FeatureManager.FeatureRevolve2(True, True, False, False, False, False, _
        swEndCondBlind, swEndCondBlind, 2 * PI, 0, False, False, 0, 0, _
        swThinWallOneDirection, 0, 0, True, True, True)
    If swFeat Is Nothing Then swApp.SendMsgToUser2 "Rotation fehlgeschlagen.", swMbWarning, swMbOk
End Sub

Bemerkungen

Vor dem Aufruf wählst du aus: die Skizze mit der Markierung 0, die Drehachse mit 4 oder 16, bei „bis Fläche“, „bis Eckpunkt“ oder „Abstand von Fläche“ das Element mit 32 und, wenn du die betroffenen Körper selbst bestimmst, jeden davon mit 1. Das Beispiel merkt sich die Mittellinie beim Zeichnen und wählt sie über ein SelectData mit der Markierung 4 aus.

Wählst du für zwei Richtungen dasselbe Element zweimal aus, hebt die zweite Auswahl die erste auf und es entsteht nichts. Dafür gibt es BothDirectionUpToSameEntity.

FeatureRevolve2 ersetzt die veralteten Befehle FeatureRevolveCut2, FeatureRevolveThin und FeatureRevolveThinCut. Winkel sind im Bogenmaß, Längen in Metern.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2011

Englisches Original: IFeatureManager::FeatureRevolve2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.