Methode · FeatureManager
FeatureExtrusionThin2-Methode (FeatureManager)
Erzeugt aus der ausgewählten Skizze ein dünnwandiges linear ausgetragenes Feature.
Syntax
Function FeatureExtrusionThin2( _
ByVal Sd As Boolean, _
ByVal Flip As Boolean, _
ByVal Dir As Boolean, _
ByVal T1 As Long, _
ByVal T2 As Long, _
ByVal D1 As Double, _
ByVal D2 As Double, _
ByVal Dchk1 As Boolean, _
ByVal Dchk2 As Boolean, _
ByVal Ddir1 As Boolean, _
ByVal Ddir2 As Boolean, _
ByVal Dang1 As Double, _
ByVal Dang2 As Double, _
ByVal OffsetReverse1 As Boolean, _
ByVal OffsetReverse2 As Boolean, _
ByVal TranslateSurface1 As Boolean, _
ByVal TranslateSurface2 As Boolean, _
ByVal Merge As Boolean, _
ByVal Thk1 As Double, _
ByVal Thk2 As Double, _
ByVal EndThk As Double, _
ByVal RevThinDir As Long, _
ByVal CapEnds As Long, _
ByVal AddBends As Boolean, _
ByVal BendRad As Double, _
ByVal UseFeatScope As Boolean, _
ByVal UseAutoSelect As Boolean, _
ByVal T0 As Long, _
ByVal StartOffset As Double, _
ByVal FlipStartOffset As Boolean _
) As FeatureSet swFeat = swFeatMgr.FeatureExtrusionThin2(True, False, False, swEndCondBlind, swEndCondBlind, 0.03, 0, _
False, False, False, False, 0, 0, False, False, False, False, True, _
0.002, 0, 0, 0, 0, False, 0, True, True, swStartSketchPlane, 0, False)Parameter
SdBooleanByValTrue: in eine Richtung.False: in zwei Richtungen.FlipBooleanByVal- Wird nicht verwendet,
Falseübergeben. DirBooleanByValTruekehrt Richtung 1 um.T1LongByVal- Endbedingung in Richtung 1, ein Wert aus
swEndConditions_e. T2LongByVal- Endbedingung in Richtung 2.
D1DoubleByVal- Tiefe in Richtung 1 in Metern.
D2DoubleByVal- Tiefe in Richtung 2 in Metern.
Dchk1BooleanByValTrue: Formschräge in Richtung 1.Dchk2BooleanByValTrue: Formschräge in Richtung 2.Ddir1BooleanByValTrue: Formschräge in Richtung 1 nach innen,Falsenach außen.Ddir2BooleanByValTrue: Formschräge in Richtung 2 nach innen,Falsenach außen.Dang1DoubleByVal- Winkel der Formschräge in Richtung 1 im Bogenmaß.
Dang2DoubleByVal- Winkel der Formschräge in Richtung 2 im Bogenmaß.
OffsetReverse1BooleanByVal- Nur bei Abstand von einer Fläche in Richtung 1:
Trueversetzt von der Skizze weg,Falsezur Skizze hin. OffsetReverse2BooleanByVal- Dasselbe für Richtung 2.
TranslateSurface1BooleanByVal- Nur bei
swEndCondOffsetFromSurfacein Richtung 1:Trueverschiebt die Referenzfläche,Falseechter Abstand. TranslateSurface2BooleanByVal- Dasselbe für Richtung 2.
MergeBooleanByValTrue: mit vorhandenen Körpern verschmelzen.False: eigener Körper.Thk1DoubleByVal- Wandstärke in Metern. Bei „Mittelebene“ gilt je Seite die Hälfte.
Thk2DoubleByVal- Zweite Wandstärke in Metern, nur bei
RevThinDir = 3. EndThkDoubleByVal- Dicke der Endkappen, nur bei
CapEnds = 1. RevThinDirLongByVal- Art der dünnen Wand:
0eine Richtung,1eine Richtung umgekehrt,2Mittelebene,3zwei Richtungen. CapEndsLongByVal1: Enden schließen (nur bei Basis-Features),0: nicht.AddBendsBooleanByValTrue: automatisch Biegungen an den Ecken offener Profile (nur bei Basis-Features).BendRadDoubleByVal- Radius der Biegungen bei
AddBends = True. UseFeatScopeBooleanByValTrue: das Feature wirkt nur auf bestimmte Körper.False: auf alle.UseAutoSelectBooleanByValTrue: SOLIDWORKS wählt die betroffenen Körper selbst.T0LongByVal- Wo die Extrusion beginnt, ein Wert aus
swStartConditions_e. StartOffsetDoubleByVal- Nur bei
swStartOffset: Abstand in Metern. FlipStartOffsetBooleanByVal- Nur bei
swStartOffset:Truekehrt die Richtung um.
Rückgabewert
Das neue Feature.
Beispiel
' Skizziert auf der vorderen Ebene einen Kreis mit 40 mm Durchmesser und extrudiert ihn 30 mm als Rohr mit 2 mm Wand.
' Vorbedingung: Ein neues, leeres Teil ist geöffnet (deutsche oder englische Vorlage).
' Ergebnis: Ein Rohrstück 40 x 2 x 30 mm.
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swSkMgr As SldWorks.SketchManager
Dim swSkizze As SldWorks.Feature
Dim swFeat As SldWorks.Feature
Dim bErfolg As Boolean
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
bErfolg = swModel.Extension.SelectByID2("Ebene vorne", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
If False = bErfolg Then bErfolg = swModel.Extension.SelectByID2("Front Plane", "PLANE", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault)
If False = bErfolg Then Exit Sub
Set swSkMgr = swModel.SketchManager
swSkMgr.InsertSketch True
swSkMgr.AddToDB = True
swSkMgr.CreateCircleByRadius 0, 0, 0, 0.02
swSkMgr.AddToDB = False
Set swSkizze = swSkMgr.ActiveSketch
swSkMgr.InsertSketch True
swSkizze.Select2 False, 0
Set swFeat = swModel.FeatureManager.FeatureExtrusionThin2(True, False, False, _
swEndCondBlind, swEndCondBlind, 0.03, 0, _
False, False, False, False, 0, 0, _
False, False, False, False, True, _
0.002, 0, 0, 0, 0, False, 0, _
True, True, swStartSketchPlane, 0, False)
If swFeat Is Nothing Then swApp.SendMsgToUser2 "Extrusion fehlgeschlagen.", swMbWarning, swMbOk
End SubBemerkungen
Mit RevThinDir = 0 liegt die Wand auf einer Seite des Kreises. Welche das ist, legt SOLIDWORKS fest, 1 nimmt die andere. Die Parameter bis TranslateSurface2 gleichen denen von FeatureManager.FeatureExtrusion3, dort sind sie in Gruppen erklärt. Längen in Metern, Winkel im Bogenmaß.
Siehe auch
Verfügbarkeit
In allen aktuellen Versionen vorhanden. Seit wann es den Befehl gibt, nennt die Hilfe nicht.
Englisches Original: IFeatureManager::FeatureExtrusionThin2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.