SolidWorksMakroprogrammierung

Eigenschaft · ConfigurationManager

ActiveConfiguration-Eigenschaft (ConfigurationManager)

Liefert die aktive Konfiguration eines Dokuments als Configuration-Objekt.

Syntax

Property ActiveConfiguration As Configuration    ' nur lesen
Set swConfig = swModel.ConfigurationManager.ActiveConfiguration

Wert

Die aktive Configuration des Dokuments.

Beispiel

' Zeigt den Namen der aktiven Konfiguration und ihre Eigenschaft "Benennung".
' Vorbedingung: Ein Teil oder eine Baugruppe ist geöffnet.
' Ergebnis:     Meldung mit Name und Wert.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swConfig As SldWorks.Configuration
    Dim sWert As String, sErgebnis As String
    Dim bAusgewertet As Boolean, bVerknuepft As Boolean

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    Set swConfig = swModel.ConfigurationManager.ActiveConfiguration
    swModel.Extension.CustomPropertyManager(swConfig.Name).Get6 "Benennung", False, sWert, sErgebnis, bAusgewertet, bVerknuepft
    swApp.SendMsgToUser2 swConfig.Name & ": " & sErgebnis, swMbInformation, swMbOk
End Sub

Bemerkungen

In einer Baugruppe ist die aktive Konfiguration der Einstieg für den Durchlauf durch alle Komponenten: danach Configuration.GetRootComponent3 und Component2.GetChildren.

Für Eigenschaften, die nur in einer Konfiguration gelten, übergibst du den Namen der Konfiguration an ModelDocExtension.CustomPropertyManager, wie im Beispiel. Mit "" bekommst du die Eigenschaften der Datei.

Die aktive Konfiguration wechselst du nicht hier, sondern mit ModelDoc2.ShowConfiguration2.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2005

Englisches Original: IConfigurationManager::ActiveConfiguration in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.