Objekt · SldWorks
ConcentricMateFeatureData-Objekt
Die Daten einer konzentrischen Verknüpfung in einer Baugruppe: die beiden Elemente, ihre Pickpunkte, die Ausrichtung und die Sperre der Drehung.
Beschreibung
Eine konzentrische Verknüpfung bringt die gewählten Elemente auf eine gemeinsame Achse und lässt sich so einstellen, dass sie die Drehung verhindert. ConcentricMateFeatureData hält ihre Daten. Übergeordnet ist MateFeatureData, das die Art der Verknüpfung liefert (swMateCONCENTRIC). Die Befehle gibt es seit SOLIDWORKS 2019.
Zugriff
AssemblyDoc.CreateMateDatamitswMateCONCENTRIC: Daten für eine neue Verknüpfung, die du anAssemblyDoc.CreateMateübergibstFeature.GetDefinition: die Daten einer vorhandenen konzentrischen Verknüpfung, TypnameMateConcentric
Beispiel
' Legt zwischen zwei ausgewählten Elementen verschiedener Komponenten eine konzentrische
' Verknüpfung an, die die Drehung sperrt.
' Vorbedingung: Eine Baugruppe ist offen, zwei passende Elemente sind ausgewählt, etwa zwei Zylinderflächen.
' Ergebnis: Eine neue konzentrische Verknüpfung im Ordner "Verknüpfungen".
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swAssy As SldWorks.AssemblyDoc
Dim swSelMgr As SldWorks.SelectionMgr
Dim swDaten As SldWorks.ConcentricMateFeatureData
Dim swFeat As SldWorks.Feature
Dim aElemente(1) As Object
Dim vElemente As Variant
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
If swModel.GetType <> swDocASSEMBLY Then Exit Sub
Set swAssy = swModel
Set swSelMgr = swModel.SelectionManager
If swSelMgr.GetSelectedObjectCount2(-1) <> 2 Then
Debug.Print "Bitte genau zwei Elemente auswählen."
Exit Sub
End If
Set aElemente(0) = swSelMgr.GetSelectedObject6(1, -1)
Set aElemente(1) = swSelMgr.GetSelectedObject6(2, -1)
vElemente = aElemente
Set swDaten = swAssy.CreateMateData(swMateCONCENTRIC)
swDaten.EntitiesToMate = vElemente
swDaten.MateAlignment = swMateAlignALIGNED
swDaten.LockRotation = True ' Drehung sperren
Set swFeat = swAssy.CreateMate(swDaten)
swModel.ClearSelection2 True
If swFeat Is Nothing Then
Debug.Print "Keine Verknüpfung entstanden."
Else
Debug.Print "Angelegt: " & swFeat.Name
swModel.EditRebuild3
End If
End SubBemerkungen
Anlegen: Folge dem Ablauf bei AssemblyDoc.CreateMate. Die Elemente setzt du mit EntitiesToMate oder wählst sie vorher mit ModelDocExtension.SelectByID2 und Markierung 1 aus. Dann setzt du die übrigen Eigenschaften.
Ändern: Mit Feature.GetDefinition holst du das MateFeatureData-Objekt und weist es einer Variablen vom Typ ConcentricMateFeatureData zu. Die Elemente änderst du dann nur über EntitiesToMate, nicht durch Auswahl. Danach rufst du Feature.ModifyDefinition auf. Löschen geht mit ModelDocExtension.DeleteSelection2.
Pickpunkte: Nach dem Setzen lassen sich ConcentricMateFeatureData.PickPoints nicht mehr ändern.
Hilfebeispiel: Das VBA-Beispiel „Create Standard Mates“ ruft CreateMateData und CreateMate über eine Variable vom Typ ModelDoc2 auf. Beide Befehle gehören zu AssemblyDoc, das Beispiel hier nimmt deshalb eine Variable vom Typ AssemblyDoc. Für die konzentrische Verknüpfung wählt das Hilfebeispiel zwei Flächen aus und setzt die Ausrichtung auf 1 (swMateAlignANTI_ALIGNED) und LockRotation auf False.
Wählst du die Mantelflächen mit ModelDocExtension.SelectByID2 an einem Punkt des Mantels aus, können stattdessen die Stirnflächen ausgewählt werden; AssemblyDoc.CreateMate liefert dann ohne Fehlermeldung Nothing. Zuverlässiger kommst du über die Flächen des Körpers mit Surface.IsCylinder und Entity.Select4 an die Mantelflächen.
Eigenschaften und Methoden
Eigenschaften 4, davon 4 beschrieben
| Name | Beschreibung |
|---|---|
| EntitiesToMate | Liest oder setzt die beiden Elemente, die eine konzentrische Verknüpfung auf eine gemeinsame Achse bringt, etwa zwei Zylinderflächen. |
| LockRotation | Liest oder setzt, ob die konzentrische Verknüpfung die Drehung der verknüpften Elemente sperrt. |
| MateAlignment | Liest oder setzt die Ausrichtung der konzentrischen Verknüpfung: gleich oder entgegengesetzt ausgerichtet. |
| PickPoints | Liest oder setzt die Pickpunkte der Elemente einer konzentrischen Verknüpfung. |
Siehe auch
Englisches Original: IConcentricMateFeatureData in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.