SolidWorksMakroprogrammierung

Objekt · SldWorks

BomFeature-Objekt

Das Feature einer Stückliste: Art, Konfigurationen, Positionsnummern, fehlende Komponenten und die Tabellen der Stückliste.

Deklaration Dim x As SldWorks.BomFeature · in der englischen .NET-Hilfe: IBomFeature

Beschreibung

BomFeature gibt Zugriff auf das Feature einer Stückliste. Hier stehen die Einstellungen, die für die ganze Stückliste gelten. Die Tabelle selbst mit Zeilen und Zellen ist eine BomTableAnnotation, die du mit BomFeature.GetTableAnnotations bekommst.

Zugriff

Beispiel

' Gibt für jede Stückliste der aktiven Zeichnung Namen, Modell, Art,
' Konfiguration und die Zeilenzahl ihrer Tabellen aus.
' Vorbedingung: Eine Zeichnung mit mindestens einer Stückliste ist offen.
' Ergebnis:     Die Werte stehen im Direktfenster.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swFeat As SldWorks.Feature
    Dim swBomFeat As SldWorks.BomFeature
    Dim swTabelle As SldWorks.TableAnnotation
    Dim vTabellen As Variant
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocDRAWING Then Exit Sub

    Set swFeat = swModel.FirstFeature
    Do While Not swFeat Is Nothing
        If swFeat.GetTypeName2 = "BomFeat" Then
            Set swBomFeat = swFeat.GetSpecificFeature2
            Debug.Print swBomFeat.Name & " zu " & swBomFeat.GetReferencedModelName
            Select Case swBomFeat.TableType
                Case swBomType_TopLevelOnly
                    Debug.Print "  Nur oberste Ebene, " & swBomFeat.GetConfigurationCount(True) & " Konfiguration(en)"
                Case swBomType_PartsOnly
                    Debug.Print "  Nur Teile, Konfiguration " & swBomFeat.Configuration
                Case swBomType_Indented
                    Debug.Print "  Eingerückt, Konfiguration " & swBomFeat.Configuration
            End Select
            vTabellen = swBomFeat.GetTableAnnotations
            If IsArray(vTabellen) Then
                For i = 0 To UBound(vTabellen)
                    Set swTabelle = vTabellen(i)                  ' dieselbe Tabelle als TableAnnotation
                    Debug.Print "  Tabelle " & i + 1 & ": " & swTabelle.RowCount & " Zeilen"
                Next i
            End If
        End If
        Set swFeat = swFeat.GetNextFeature
    Loop
End Sub

Bemerkungen

Art der Stückliste: Welche Eigenschaften gelten, hängt von BomFeature.TableType ab. Stücklisten „Nur Teile“ und „Eingerückt“ zeigen genau eine Konfiguration, die liest und setzt du mit BomFeature.Configuration. Eine Stückliste „Nur oberste Ebene“ kann mehrere Konfigurationen mit je einer Mengenspalte zeigen, dafür gibt es BomFeature.GetConfigurations und BomFeature.SetConfigurations. Nur für sie gilt BomFeature.DisplayAsOneItem, nur für eingerückte Stücklisten BomFeature.NumberingTypeOnIndentedBOM.

Fehlende Komponenten: Fehlende Komponenten sind unterdrückte Komponenten. BomFeature.StrikeoutMissingItems und BomFeature.KeepReplacedCompOption gelten nur, wenn BomFeature.KeepMissingItems True ist.

Tabellen: Zeilen, Spalten und Zellen liest du nicht am Feature, sondern an den Tabellen aus BomFeature.GetTableAnnotations. Das Hilfebeispiel „Export BOMs to XML“ weist sie dafür, wie oben, einer Variablen vom Typ TableAnnotation zu.

Auswählen: Wählst du die Stückliste mit ModelDocExtension.SelectByID2 über ihren Namen und den Typ BOMFEATURE aus, liefert SelectionMgr.GetSelectedObject6 sie direkt als BomFeature (Auswahltyp 97). Mit „Name@Ansicht“ klappte die Auswahl nicht.

Eigenschaften und Methoden

Eigenschaften 16, davon 16 beschrieben

NameBeschreibung
ConfigurationLiest oder setzt die Konfiguration, die die Stückliste zeigt. Gilt nur für Stücklisten mit einer Konfiguration.
DetailedCutListLiest oder setzt, ob die Stückliste die detaillierte Zuschnittsliste zeigt.
DisplayAsOneItemLiest oder setzt, ob alle Konfigurationen einer Komponente unter derselben Positionsnummer erscheinen. Gilt nur für Stücklisten „Nur oberste Ebene“.
DissolvePartLevelRowsLiest oder setzt, ob die Stückliste die Zeilen von Schweißkonstruktions-Teilen auflöst.
FollowAssemblyOrder2Liest oder setzt, ob die Positionsnummern der Stückliste der Reihenfolge im FeatureManager der Baugruppe folgen.
KeepCurrentItemNumbersLiest oder setzt, ob die Positionsnummern beim Umsortieren der Zeilen bei ihren Komponenten bleiben.
KeepMissingItemsLiest oder setzt, ob die Stückliste fehlende Komponenten behält, also unterdrückte Komponenten.
KeepReplacedCompOptionLiest oder setzt, wie die Stückliste mit ersetzten Komponenten umgeht, wenn sie fehlende Komponenten behält.
NameLiefert den Namen des Stücklisten-Features.
NumberingTypeOnIndentedBOMLiest oder setzt, wie eine eingerückte Stückliste ihre Zeilen nummeriert: gar nicht, detailliert oder flach.
PartConfigurationGroupingLiest oder setzt, wie die Stückliste verschiedene Konfigurationen desselben Teils gruppiert.
RoutingComponentGroupingLiest oder setzt, wie die Stückliste Routing-Komponenten gruppiert und anzeigt, etwa Rohre und Leitungen.
SequenceStartNumberLiest oder setzt, mit welcher Positionsnummer die Stückliste zu zählen beginnt.
StrikeoutMissingItemsLiest oder setzt, ob die Stückliste fehlende Komponenten durchstreicht.
TableTypeLiest oder setzt die Art der Stückliste: nur oberste Ebene, nur Teile oder eingerückt.
ZeroQuantityDisplayLiest oder setzt, was die Stückliste zeigt, wenn ein Wert 0 ist: einen Strich, die Zahl 0 oder nichts.

Methoden 10, davon 9 beschrieben, 1 veraltet

NameBeschreibung
FollowAssemblyOrderveraltet ersetzt durch BomFeature.FollowAssemblyOrder2
GetConfigurationCountLiefert, wie viele Konfigurationen die Stückliste zeigt oder zeigen könnte.
GetConfigurationsLiefert die Namen der Konfigurationen, die die Stückliste zeigt oder zeigen könnte, und welche davon sie zeigt.
GetFeatureLiefert das Feature der Stückliste.
GetLinkToDisplayStateLiefert den Anzeigezustand, mit dem die Stückliste verknüpft ist.
GetReferencedModelNameLiefert den Namen des Modells, auf das sich die Stückliste bezieht.
GetTableAnnotationCountLiefert, aus wie vielen Tabellen die Stückliste besteht.
GetTableAnnotationsLiefert die Tabellen der Stückliste.
SetConfigurationsLegt fest, welche Konfigurationen die Stückliste zeigt.
SetLinkToDisplayStateVerknüpft die Stückliste mit einem Anzeigezustand.

Nicht aufgeführt sind 3 C++-Varianten (Namen mit I davor, zum Beispiel IGetConfigurations). In VBA nimmst du immer den Befehl ohne I.

Siehe auch

Englisches Original: IBomFeature in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.