SolidWorksMakroprogrammierung

Methode · View

MergeBendTags-Methode (View)

Fasst Biegemarkierungen in der Zeichnung eines Blechteils zusammen oder hebt eine Zusammenfassung wieder auf.

Syntax

Function MergeBendTags( _
   ByVal Merge As Boolean, _
   ByVal BendNotes As Variant _
) As Boolean
bErfolg = swView.MergeBendTags(True, swNotizen)

Parameter

MergeBooleanByVal
True fasst die Biegemarkierungen zusammen, False hebt eine zusammengefasste Biegemarkierung wieder auf.
BendNotesVariantByVal
Array mit den Biegemarkierungen als Note-Objekte. Zum Zusammenfassen zwei oder mehr, zum Aufheben genau eine zusammengefasste Biegemarkierung.

Rückgabewert

Die Hilfe nennt True, wenn die Biegemarkierungen zusammengefasst wurden bzw. die Zusammenfassung aufgehoben wurde, sonst False. In SOLIDWORKS 2024 kam in allen Versuchen False, und an den Biegemarkierungen änderte sich nichts (siehe unten).

Beispiel

' swModel ist die aktive Zeichnung (ModelDoc2), swView die Zeichenansicht mit den Biegemarkierungen (View).
' Vorher genau zwei Biegemarkierungen in dieser Ansicht auswählen.
Dim swSelMgr As SldWorks.SelectionMgr
Dim swNotizen(1) As SldWorks.Note
Dim bErfolg As Boolean
Set swSelMgr = swModel.SelectionManager
Set swNotizen(0) = swSelMgr.GetSelectedObject6(1, -1)
Set swNotizen(1) = swSelMgr.GetSelectedObject6(2, -1)
If swNotizen(0).IsBendLineNote And swNotizen(1).IsBendLineNote Then
    ' die Ansicht zur Auswahl hinzufügen
    bErfolg = swModel.Extension.SelectByID2(swView.GetName2, "DRAWINGVIEW", 0, 0, 0, True, 0, Nothing, 0)
    bErfolg = swView.MergeBendTags(True, swNotizen)
    swModel.EditRebuild3
    Debug.Print "Zusammengefasst: " & bErfolg
End If

Bemerkungen

So gehst du vor:

  • Zusammenfassen: die Biegemarkierungen auswählen, dann die Zeichenansicht auswählen, in der sie liegen, die Methode mit Merge = True aufrufen und danach die Zeichnung neu aufbauen (ModelDoc2.EditRebuild3).
  • Aufheben: die Zeichenansicht mit der zusammengefassten Biegemarkierung auswählen und aktivieren (DrawingDoc.ActivateView), die zusammengefasste Biegemarkierung auswählen und die Methode mit Merge = False aufrufen.

Ob die Biegemarkierungen beim Aufruf zusätzlich zum Array noch ausgewählt sein müssen, lässt die Hilfe offen. Die Biegemarkierungen sind Hinweise (Note). Ob ein Hinweis ein Biegehinweis ist, sagt Note.IsBendLineNote.

Der Befehl liefert False auch mit ausgewählten Biegemarkierungen und ausgewählter Ansicht, mit dem Array als Object oder Variant und beim Aufheben mit Merge = False. In der Oberfläche fasst du Biegemarkierungen über das Kontextmenü „Biegungsbezugshinweise verschmelzen“ zusammen.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2013

Englisches Original: IView::MergeBendTags in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.