SolidWorksMakroprogrammierung

Methode · View

GetDimensionDisplayInfo5-Methode (View)

Liefert die Geometrie aller Bemaßungen einer Zeichenansicht oder eines Blatts: Linien, Bögen, Pfeile und Textpositionen.

Syntax

Function GetDimensionDisplayInfo5() As Variant
vInfo = swView.GetDimensionDisplayInfo5

Rückgabewert

Array mit Double-Werten. An Index 0 steht die Anzahl der Bemaßungen. Danach folgt jede Bemaßung so:

  • Anzahl der Linien (Hilfslinien und Führungslinien), danach je Linie die Anzahl ihrer Segmente und je Segment 6 Werte: Start X, Y, Z und Ende X, Y, Z
  • Anzahl der Bögen (bogenförmige Führungslinien), danach je Bogen die Anzahl seiner Segmente und je Segment 9 Werte: Mittelpunkt, Start und Ende mit je X, Y, Z
  • Anzahl der Pfeile, danach je Pfeil 8 Werte: Spitze X, Y, Z, Richtung X, Y, Z, Breite, Höhe
  • 70 feste Werte, hier gezählt ab 0:
  • 0: Toleranzart aus swTolType_e, etwa swTolNONE (0) oder swTolBASIC (1)
  • 1: doppelte Bemaßung ja oder nein
  • 2: Klammern angezeigt ja oder nein
  • 3: Winkel des Texts im Bogenmaß, gegen den Uhrzeigersinn ab der positiven X-Achse
  • 4 bis 27: je X, Y, Z die Position von Wert, oberer und unterer Abweichung, dann dasselbe für den zweiten Wert der doppelten Bemaßung, dann Präfix und Suffix
  • 28 bis 39: je zwei Ecken von Toleranzrahmen 1 und 2, bei Toleranzart swTolBASIC
  • 40 bis 63: die zwei Klammerbögen, je Startpunkt, Endpunkt, Mittelpunkt und Bezugsrichtung
  • 64 bis 69: Position des Texts über und des Texts unter der Bemaßung

Alle Textpositionen sind die linke obere Ecke des Texts. Die Werte zum zweiten Wert und zu Toleranzrahmen 2 gelten nur bei doppelter Bemaßung, die Klammerbögen nur, wenn Klammern angezeigt werden, etwa bei einer Referenzbemaßung.

Beispiel

' swView ist eine Zeichenansicht (View), etwa aus DrawingDoc.ActiveDrawingView oder der Auswahl.
Dim vInfo As Variant
Dim lIdx As Long, i As Long, j As Long
Dim lLinien As Long, lBoegen As Long, lPfeile As Long, lAnzahl As Long
vInfo = swView.GetDimensionDisplayInfo5
If IsArray(vInfo) Then
    If UBound(vInfo) >= 0 Then lAnzahl = vInfo(0)  ' ohne Bemaßungen ein leeres Array
    lIdx = 1                                       ' vInfo(0) ist die Anzahl der Bemaßungen
    For i = 1 To lAnzahl
        lLinien = vInfo(lIdx)
        lIdx = lIdx + 1
        For j = 1 To lLinien                       ' je Linie die Anzahl ihrer Segmente, dann 6 Werte je Segment
            lIdx = lIdx + 1 + 6 * vInfo(lIdx)
        Next j
        lBoegen = vInfo(lIdx)
        lIdx = lIdx + 1
        For j = 1 To lBoegen                       ' je Bogen die Anzahl seiner Segmente, dann 9 Werte je Segment
            lIdx = lIdx + 1 + 9 * vInfo(lIdx)
        Next j
        lPfeile = vInfo(lIdx)
        lIdx = lIdx + 1 + 8 * lPfeile                ' lIdx zeigt jetzt auf die Toleranzart
        Debug.Print "Bemaßung " & i & ": " & lLinien & " Linien, " & lBoegen & " Bögen, " & lPfeile & _
            " Pfeile, Wert bei " & Format(vInfo(lIdx + 4) * 1000, "0.0") & " / " & Format(vInfo(lIdx + 5) * 1000, "0.0") & " mm"
        lIdx = lIdx + 70                           ' weiter zur nächsten Bemaßung
    Next i
End If

Bemerkungen

Aufbau: Die Hilfe nennt in ihrer Formel eine Segmentzahl je Linie und je Bogen, in ihrer ausgeschriebenen Musterliste fehlt diese Zahl. Richtig ist die Formel (bei Linien: jede Linie begann mit 1, danach kamen 6 Koordinaten). Einheiten: Punkte und Pfeilgrößen sind in Metern, die Punkte in Blattkoordinaten (Pfeile 0,0033 × 0,00144, die Hilfslinien einer 100 mm breiten Ansicht mit der Mitte bei 120/180 mm lagen bei x 0,07 bis 0,17). Der Textwinkel steht im Bogenmaß. Ja-oder-nein-Werte stehen als Zahl im Array. Welche Zahl für ja steht, sagt die Hilfe nicht, prüf deshalb auf <> 0.

Die Hilfe sagt, der Befehl gilt für das aktuelle Blatt oder die aktuelle Zeichenansicht, vermutlich also für das View-Objekt, für das du ihn aufrufst. Bohrungsbeschreibungen unterstützt er nicht. Die Texte selbst liefert View.GetDimensionDisplayString5.

Ersetzt View.GetDimensionDisplayInfo4.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2005

Englisches Original: IView::GetDimensionDisplayInfo5 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.