SolidWorksMakroprogrammierung

Objekt · SldWorks

TwoMemberCornerTreatmentFeatureData-Objekt

Die Definition einer Eckenbehandlung in einem Tragwerk, an der sich genau zwei Elemente treffen: Trimmart, Schweißspalt und welches Element trimmt.

Deklaration Dim x As SldWorks.TwoMemberCornerTreatmentFeatureData · in der englischen .NET-Hilfe: ITwoMemberCornerTreatmentFeatureData

Beschreibung

TwoMemberCornerTreatmentFeatureData gibt Zugriff auf eine Ecke mit zwei Elementen in einem Tragwerk (structure system). Das ist die Stelle, an der sich zwei Elemente schneiden. Ein Element wird zum Trimmwerkzeug und fügt am anderen Material hinzu oder nimmt es weg. Beim ebenen Trimmen und beim Trimmen am Körper kann jedes der beiden das Werkzeug sein. Als dritte Art gibt es hier den Gehrungsschnitt. Die Befehle mit eigener Hilfeseite gibt es seit SOLIDWORKS 2023.

Zugriff

Beispiel

' Geht alle Eckenverwaltungen des Teils durch und gibt für jede Ecke mit zwei
' Elementen Trimmart, Schweißspalt und die beiden Elemente aus.
' Vorbedingung: Ein Teil mit einem Tragwerk und mindestens einer Ecke mit zwei Elementen ist offen.
' Ergebnis:     Die Ecken stehen im Direktfenster. Das Teil bleibt unverändert.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swOrdnerFeat As SldWorks.Feature
    Dim swVerwaltung As SldWorks.CornerManagementFolder
    Dim swGruppe As SldWorks.CornerTreatmentGroupFolder
    Dim swEckFeat As SldWorks.Feature
    Dim swDaten As SldWorks.CornerTreatmentFeatureData
    Dim swZwei As SldWorks.TwoMemberCornerTreatmentFeatureData
    Dim swElement As SldWorks.CornerMember
    Dim vOrdner As Variant, vGruppen As Variant, vEcken As Variant, vElemente As Variant
    Dim i As Long, k As Long, x As Long, j As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocPART Then Exit Sub

    vOrdner = swModel.FeatureManager.GetCornerManagementFolders
    If Not IsArray(vOrdner) Then Exit Sub
    For i = 0 To UBound(vOrdner)
        Set swOrdnerFeat = vOrdner(i)
        Set swVerwaltung = swOrdnerFeat.GetSpecificFeature2
        vGruppen = swVerwaltung.GetTreatmentGroupFolders
        If IsArray(vGruppen) Then
            For k = 0 To UBound(vGruppen)
                Set swGruppe = vGruppen(k)
                vEcken = swGruppe.GetCornerTreatments
                If IsArray(vEcken) Then
                    For x = 0 To UBound(vEcken)
                        Set swEckFeat = vEcken(x)
                        Set swDaten = swEckFeat.GetDefinition
                        If swDaten.CornerType = swCorner_TwoMember Then
                            swDaten.AccessSelections swModel, Nothing
                            Set swZwei = swDaten                         ' dieselbe Definition
                            Debug.Print swEckFeat.Name & ": Trimmart " & swZwei.CornerTreatmentTrimType & _
                                        ", Schweißspalt " & swZwei.WeldTrimGap * 1000 & " mm"
                            vElemente = swZwei.GetCornerGroupMembers
                            If IsArray(vElemente) Then
                                For j = 0 To UBound(vElemente)
                                    Set swElement = vElemente(j)
                                    Debug.Print "  " & swElement.GetUnderlyingMemberFeature.Name & _
                                                ", Reihenfolge " & swElement.TrimOrder
                                Next j
                            End If
                            swDaten.ReleaseSelectionAccess               ' nichts geändert
                        End If
                    Next x
                End If
            Next k
        End If
    Next i
End Sub

Bemerkungen

Abgeleitete Schnittstelle: TwoMemberCornerTreatmentFeatureData ist von CornerTreatmentFeatureData abgeleitet und gilt nur, wenn deren IgnoreCornerTreatment False ist. AccessSelections, ReleaseSelectionAccess und CornerType rufst du wie im Hilfebeispiel „Access Structure System Corner Treatments“ an der CornerTreatmentFeatureData auf, die übrigen Befehle an derselben Definition als TwoMemberCornerTreatmentFeatureData. Zum Ändern übergibst du die CornerTreatmentFeatureData an Feature.ModifyDefinition.

Drei Listen: Der PropertyManager zeigt für Ecken mit zwei Elementen drei Listen: die Eckgruppen, die Elemente der Eckgruppe und den Punkt für die Gehrungsebene. Die Eckgruppen erreichst du über CornerTreatmentGroupFolder, die beiden anderen über dieses Objekt.

Lücken in der Hilfe: CornerTreatmentTrimType, PlanarTrimOption, MiterTrimPlanePoint und GetCornerGroupMembers haben in der .NET-Hilfe keine eigene Seite. Was auf ihren Seiten steht, stützt sich auf das Hilfebeispiel und die gleichnamigen Befehle für einfache Ecken (SimpleCornerTreatmentFeatureData).

Einheiten: Für den Schweißspalt nennt die Hilfe keine Einheit. Das Hilfebeispiel setzt 0.001. Es sind Meter (0,001 ergab einen Spalt von 1 mm, das Volumen sank um 535 mm³ bei 576 mm² Rohrquerschnitt).

Das Beispiel ruft TwoMemberCornerTreatmentFeatureData.GetCornerGroupMembers auf; nach CornerTreatmentFeatureData.AccessSelections bringt dieser Aufruf SOLIDWORKS zum Absturz.

Eigenschaften und Methoden

Eigenschaften 4, davon 4 beschrieben

NameBeschreibung
CornerTreatmentTrimTypeLiest oder setzt, wie die Ecke mit zwei Elementen getrimmt wird: eben, am Körper oder mit Gehrung.
MiterTrimPlanePointLiest oder setzt den Punkt, der die Ebene des Gehrungsschnitts festlegt.
PlanarTrimOptionLiest oder setzt, wo die Ecke beim ebenen Trimmen schneidet: beim ersten oder beim vollständigen Kontakt.
WeldTrimGapLiest oder setzt den Schweißspalt zwischen den beiden Elementen der Ecke.

Methoden 2, davon 2 beschrieben

NameBeschreibung
GetCornerGroupMembersLiefert die beiden Elemente der Ecke.
SwapMembersMacht das andere der beiden Elemente zum Trimmwerkzeug.

Siehe auch

Englisches Original: ITwoMemberCornerTreatmentFeatureData in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.