Objekt · SldWorks
TitleBlock-Objekt
Das Schriftfeld eines Zeichenblatts: sein Feature, die Notizen darin und sein Bereich im Blattformat.
Beschreibung
TitleBlock gibt Zugriff auf das Schriftfeld eines Zeichenblatts. Das Schriftfeld fasst Notizen zusammen, etwa Zeichnungsnummer oder Benennung, und hat einen rechteckigen Bereich im Blattformat. Je Blatt gibt es nur ein Schriftfeld. Mit einer Schriftfeldtabelle in Teilen und Baugruppen (TitleBlockTableFeature) hat das Objekt nichts zu tun. Die Befehle gibt es seit SOLIDWORKS 2009.
Zugriff
Sheet.TitleBlock: das Schriftfeld eines Blatts, sonstNothingSheet.InsertTitleBlock: legt ein Schriftfeld aus Notizen an
Beispiel
' Gibt Bereich und Notizen des Schriftfelds auf dem aktuellen Blatt aus.
' Vorbedingung: Eine Zeichnung mit Schriftfeld ist offen.
' Ergebnis: Die Angaben stehen im Direktfenster, die Zeichnung bleibt unverändert.
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swZeichnung As SldWorks.DrawingDoc
Dim swBlatt As SldWorks.Sheet
Dim swSchriftfeld As SldWorks.TitleBlock
Dim swNotiz As SldWorks.Note
Dim vNotizen As Variant
Dim dX1 As Double, dY1 As Double, dX2 As Double, dY2 As Double
Dim i As Long
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
If swModel.GetType <> swDocDRAWING Then Exit Sub
Set swZeichnung = swModel
Set swBlatt = swZeichnung.GetCurrentSheet
Set swSchriftfeld = swBlatt.TitleBlock
If swSchriftfeld Is Nothing Then
Debug.Print "Das Blatt hat kein Schriftfeld."
Exit Sub
End If
swSchriftfeld.GetExtents dX1, dY1, dX2, dY2
Debug.Print swSchriftfeld.GetFeature.Name & ": oben links " & dX1 * 1000 & " / " & dY1 * 1000 & _
", unten rechts " & dX2 * 1000 & " / " & dY2 * 1000 & " mm"
vNotizen = swSchriftfeld.GetNotes
If IsArray(vNotizen) Then
For i = 0 To UBound(vNotizen)
Set swNotiz = vNotizen(i)
Debug.Print " " & swNotiz.GetName & ": " & swNotiz.GetText
Next i
End If
End SubBemerkungen
Anlegen: Das Hilfebeispiel „Get Notes from New or Existing Title Block“ prüft mit Sheet.TitleBlock, ob es ein Schriftfeld gibt. Wenn nicht, legt es mit Sheet.InsertTitleBlock eines aus den ersten beiden Notizen der ersten Ansicht (DrawingDoc.GetFirstView, View.GetNotes) an. InsertTitleBlock kann eine oder mehrere Note-Objekte oder nichts bekommen.
Einheiten: Für den Bereich nennt die Hilfe keine Einheit. Es sind Meter in Blattkoordinaten (der Bereich lag bei 126 / 89,1 bis 420 / 0 mm auf einem A3-Blatt, SetExtents mit X1 - 0,01 verschob die linke Kante um 10 mm).
Eigenschaften und Methoden
Methoden 5, davon 5 beschrieben
| Name | Beschreibung |
|---|---|
| GetExtents | Liefert die Ecken des Bereichs, den das Schriftfeld im Blattformat einnimmt. |
| GetFeature | Liefert das Feature des Schriftfelds. |
| GetNoteCount | Liefert die Zahl der Notizen im Schriftfeld. |
| GetNotes | Liefert die Notizen im Schriftfeld. |
| SetExtents | Setzt die Ecken des Bereichs, den das Schriftfeld im Blattformat einnimmt. |
Nicht aufgeführt sind 1 C++-Varianten (Namen mit I davor, zum Beispiel IGetNotes). In VBA nimmst du immer den Befehl ohne I.
Siehe auch
Englisches Original: ITitleBlock in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.