SolidWorksMakroprogrammierung

Objekt · SldWorks

SwOLEObject-Objekt

Ein OLE-Objekt in einem Dokument, etwa eine eingebettete oder verknüpfte Excel-Tabelle: Daten, Lage, Verknüpfung, Auswahl und Aktivieren.

Deklaration Dim x As SldWorks.SwOLEObject · in der englischen .NET-Hilfe: ISwOLEObject

Beschreibung

SwOLEObject gibt Zugriff auf ein OLE-Objekt in einem Teil, einer Baugruppe oder einer Zeichnung, etwa eine Excel-Tabelle oder ein Bild. Ein OLE-Objekt ist entweder in das Dokument eingebettet oder mit einer externen Datei verknüpft. Du liest seine Daten und seine Lage, wählst es aus, aktualisierst es aus der Datei oder öffnest es in seiner Anwendung. Die Befehle gibt es seit SOLIDWORKS 2006.

Zugriff

Beispiel

' Gibt für jedes OLE-Objekt des aktiven Dokuments Klassen-ID, Datengröße,
' Darstellung und Verknüpfung aus.
' Vorbedingung: Ein Dokument mit einem oder mehreren OLE-Objekten ist offen.
' Ergebnis:     Je OLE-Objekt ein Block im Direktfenster (Strg+G).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swOle As SldWorks.SwOLEObject
    Dim vObjekte As Variant
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    vObjekte = swModel.Extension.GetOLEObjects(swOleObjectOptions_GetAll)
    If IsEmpty(vObjekte) Then
        Debug.Print "Keine OLE-Objekte"
        Exit Sub
    End If

    For i = 0 To UBound(vObjekte)
        Set swOle = vObjekte(i)
        Debug.Print "OLE-Objekt " & i + 1 & ": Klasse " & swOle.Clsid & ", " & swOle.BufferSize & " Byte, Darstellung " & swOle.Aspect
        If swOle.IsLinked Then
            Debug.Print "  verknüpft mit " & swOle.FileName
        Else
            Debug.Print "  eingebettet"
        End If
    Next i
End Sub

Bemerkungen

Darstellung: SwOLEObject.Aspect liefert einen Wert der Windows-Aufzählung DVASPECT: 1 Inhalt, 2 Miniatur, 4 Symbol, 8 Druckansicht. Eine SOLIDWORKS-Konstante dafür gibt es nicht.

Koordinaten: SwOLEObject.Boundaries liefert bei Zeichnungen Blattkoordinaten, bei Teilen und Baugruppen Bildschirmpixel.

Hilfebeispiele: Das Hilfebeispiel „Determine If OLE Objects are Linked or Embedded“ fragt in seiner Schleife immer vOleObjs(0) ab statt vOleObjs(i). Das Beispiel oben nimmt den Zähler.

Eigenschaften und Methoden

Eigenschaften 7, davon 7 beschrieben

NameBeschreibung
AspectLiefert, wie das OLE-Objekt dargestellt wird: Inhalt, Miniatur, Symbol oder Druckansicht.
BoundariesLiest oder setzt die Lage des OLE-Objekts im Dokument.
BufferLiefert die Daten des OLE-Objekts.
BufferSizeLiefert die Größe der Daten des OLE-Objekts.
ClsidLiefert die Klassen-ID des OLE-Objekts.
FileNameLiefert Pfad und Namen der Datei, mit der das OLE-Objekt verknüpft ist.
IsLinkedLiefert, ob das OLE-Objekt mit einer externen Datei verknüpft oder in das Dokument eingebettet ist.

Methoden 3, davon 3 beschrieben

NameBeschreibung
RefreshLädt die Daten des OLE-Objekts neu aus der verknüpften Datei.
SelectWählt das OLE-Objekt aus.
SetActiveAktiviert das OLE-Objekt in seiner Anwendung oder deaktiviert es.

Nicht aufgeführt sind 3 C++-Varianten (Namen mit I davor, zum Beispiel IGetBoundaries). In VBA nimmst du immer den Befehl ohne I.

Siehe auch

Englisches Original: ISwOLEObject in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.