Objekt · SldWorks
SheetMetalGaugeTableParameters-Objekt
Die Einstellungen der Blechstärkentabelle eines Blech-Features: Tabellendatei, gewählte Blechstärke, Blechdicke und Biegeradius, auf Wunsch überschrieben.
Beschreibung
SheetMetalGaugeTableParameters gibt Zugriff auf die Parameter einer Blechstärkentabelle (gauge table). Eine solche Tabelle listet Blechstärken (gauge numbers), zu jeder eine Blechdicke und einen oder mehrere Biegeradien. Du wählst eine Blechstärke aus der Tabelle oder überschreibst Dicke und Radius mit eigenen Werten. Die Befehle gibt es seit SOLIDWORKS 2021.
Zugriff
SweptFlangeFeatureData.GetGaugeTableParameters: bei einer ausgetragenen Lasche, zurück gibst du die Werte mitSweptFlangeFeatureData.SetGaugeTableParameters
Beispiel
' Gibt Tabelle, verfügbare Blechstärken und Radien der ausgewählten ausgetragenen Lasche aus
' und wählt danach die erste Blechstärke der Tabelle.
' Vorbedingung: Ein Teil ist offen, eine ausgetragene Lasche mit Blechstärkentabelle ist ausgewählt.
' Ergebnis: Die Lasche nutzt die erste Blechstärke, die Werte stehen im Direktfenster.
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swFeat As SldWorks.Feature
Dim swDaten As SldWorks.SweptFlangeFeatureData
Dim swTabelle As SldWorks.SheetMetalGaugeTableParameters
Dim sPfad As String
Dim vStaerken As Variant
Dim vRadien As Variant
Dim i As Long
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
Set swFeat = swModel.SelectionManager.GetSelectedObject6(1, -1)
If swFeat Is Nothing Then Exit Sub
Set swDaten = swFeat.GetDefinition
If False = swDaten.UseGaugeTable Then Exit Sub
If False = swDaten.AccessSelections(swModel, Nothing) Then Exit Sub
Set swTabelle = swDaten.GetGaugeTableParameters
If swTabelle.GetGaugeTablePath(sPfad) Then Debug.Print "Tabelle: " & sPfad
Debug.Print "Verfahren: " & swTabelle.Process & ", aktuell: " & swTabelle.GetCurrentGaugeNumber & _
", Dicke " & swTabelle.GetThickness * 1000 & " mm"
vStaerken = swTabelle.GetAvailableGaugeNumbers
For i = 0 To swTabelle.GetGaugeNumberCount - 1
Debug.Print " " & vStaerken(i)
Next i
If swTabelle.SetCurrentGaugeNumber(vStaerken(0)) Then
vRadien = swTabelle.GetAvailableRadii
If swTabelle.GetRadiiCount > 0 Then Debug.Print "Erster Radius der neuen Blechstärke: " & vRadien(0)
swDaten.SetGaugeTableParameters swTabelle
If False = swFeat.ModifyDefinition(swDaten, swModel, Nothing) Then swDaten.ReleaseSelectionAccess
Else
swDaten.ReleaseSelectionAccess
End If
End SubBemerkungen
Hilfebeispiel: Auf der Hilfeseite des Objekts steht ein VBA-Beispiel. Es legt in einem neuen Teil eine ausgetragene Lasche mit der mitgelieferten Tabelle BEND ALLOWANCE MM SAMPLE.XLS an, gibt alle Werte aus, wählt „Gauge 3“, überschreibt Dicke und Radius mit 0.006 und dreht die Richtung um.
Blechstärke oder eigene Werte: Die Blechdicke wechselst du normalerweise über eine andere Blechstärke (SheetMetalGaugeTableParameters.SetCurrentGaugeNumber), denn jede Blechstärke hat eine Standarddicke. Eigene Werte setzt du mit SheetMetalGaugeTableParameters.SetThickness und SheetMetalGaugeTableParameters.SetRadius und True für Override.
Einheiten: Für Dicke und Radius nennt die Hilfe keine Einheit; es sind Meter. Die verfügbaren Radien liefert sie als Texte, ebenfalls in Metern (etwa „0,001“).
Mehr dazu: Die Hilfe verweist auf das Thema „Sheet Metal Gauge Tables“ in der Hilfe zur Oberfläche.
In SOLIDWORKS 2024 gibt es die Tabelle „bend allowance mm sample.xls“ aus dem Hilfebeispiel nicht mehr, nur .xlsx-Dateien. In der deutschen Fassung liefert SheetMetalGaugeTableParameters.SetGaugeTablePath auch mit der englischen .xlsx-Tabelle False; nimm eine Tabelle aus dem deutschen Ordner, etwa „k-factor mm sample.xlsx“.
Eigenschaften und Methoden
Eigenschaften 4, davon 4 beschrieben
| Name | Beschreibung |
|---|---|
| OverrideRadius | Liefert, ob der Biegeradius der Blechstärkentabelle mit einem eigenen Wert überschrieben ist. |
| OverrideThickness | Liefert, ob die Blechdicke der Blechstärkentabelle mit einem eigenen Wert überschrieben ist. |
| Process | Liefert das Blechverfahren der Blechstärkentabelle. |
| ReverseDirection | Liest oder setzt, ob die Blechdicke in die andere Richtung aufgetragen wird. |
Methoden 12, davon 12 beschrieben
| Name | Beschreibung |
|---|---|
| GetAvailableGaugeNumbers | Liefert die Blechstärken, die in der Blechstärkentabelle stehen. |
| GetAvailableRadii | Liefert die Biegeradien, die die Tabelle für die gewählte Blechstärke anbietet. |
| GetCurrentGaugeNumber | Liefert die gewählte Blechstärke der Blechstärkentabelle. |
| GetCurrentRadius | Liefert den aktuellen Biegeradius für die gewählte Blechstärke. |
| GetGaugeNumberCount | Liefert die Zahl der Blechstärken in der Blechstärkentabelle. |
| GetGaugeTablePath | Liefert Pfad und Dateiname der Blechstärkentabelle. |
| GetRadiiCount | Liefert die Zahl der Biegeradien, die die Tabelle für die gewählte Blechstärke anbietet. |
| GetThickness | Liefert die Blechdicke für die gewählte Blechstärke. |
| SetCurrentGaugeNumber | Wählt eine Blechstärke aus der Blechstärkentabelle. |
| SetGaugeTablePath | Setzt Pfad und Dateiname der Blechstärkentabelle. |
| SetRadius | Setzt den Biegeradius, entweder einen aus der Tabelle oder einen eigenen. |
| SetThickness | Setzt die Blechdicke als eigenen Wert, abweichend von der Blechstärke der Tabelle. |
Siehe auch
Englisches Original: ISheetMetalGaugeTableParameters in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.