SolidWorksMakroprogrammierung

Objekt · SldWorks

SecondaryStructuralMemberFeatureData-Objekt

Die Daten eines sekundären Elements in einem Tragwerk: die Art, wie es erzeugt wird.

Deklaration Dim x As SldWorks.SecondaryStructuralMemberFeatureData · in der englischen .NET-Hilfe: ISecondaryStructuralMemberFeatureData

Beschreibung

SecondaryStructuralMemberFeatureData gibt Zugriff auf ein sekundäres Element eines Tragwerks (structure system). Sekundäre Elemente liegen zwischen primären Elementen oder reichen bis zu ihnen. Das Objekt sitzt zwischen den allgemeinen Daten eines Elements (StructureSystemMemberFeatureData) und den Daten der einzelnen Erzeugungsarten. Die Befehle für Tragwerke gibt es seit SOLIDWORKS 2022.

Zugriff

Beispiel

' Geht alle Elemente des ausgewählten Tragwerks durch und gibt bei den sekundären
' Elementen die Erzeugungsart aus.
' Vorbedingung: Ein Teil mit einem Tragwerk ist offen, das Tragwerk ist im
'               FeatureManager ausgewählt.
' Ergebnis:     Je sekundärem Element eine Zeile im Direktfenster (Strg+G).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSelMgr As SldWorks.SelectionMgr
    Dim swFeat As SldWorks.Feature
    Dim swTragwerk As SldWorks.StructureSystemFolder
    Dim swGruppenFeat As SldWorks.Feature
    Dim swGruppe As SldWorks.ProfileGroupFolder
    Dim swElement As SldWorks.StructureSystemMemberFeatureData
    Dim swSekundaer As SldWorks.SecondaryStructuralMemberFeatureData
    Dim vGruppen As Variant, vElemente As Variant
    Dim i As Long, j As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    Set swSelMgr = swModel.SelectionManager
    Set swFeat = swSelMgr.GetSelectedObject6(1, -1)
    If swFeat Is Nothing Then Exit Sub
    Set swTragwerk = swFeat.GetSpecificFeature2
    If swTragwerk Is Nothing Then Exit Sub

    vGruppen = swTragwerk.GetProfileGroupFolders
    If IsEmpty(vGruppen) Then Exit Sub
    For i = 0 To UBound(vGruppen)
        Set swGruppenFeat = vGruppen(i)                   ' wie in den Hilfebeispielen
        Set swGruppe = swGruppenFeat.GetSpecificFeature2
        vElemente = swGruppe.GetStructureSystemMembers
        If Not IsEmpty(vElemente) Then
            For j = 0 To UBound(vElemente)
                Set swElement = vElemente(j)
                If swElement.StructureSystemMemberType = swStructureSystemMemberType_Secondary Then
                    Set swSekundaer = swElement           ' dieselben Daten, anderer Typ
                    Select Case swSekundaer.SecondaryMemberType
                        Case swStructureSystemMemberCreationType_Secondary_SupportPlane
                            Debug.Print swElement.GetFeature.Name & ": Stützebene"
                        Case swStructureSystemMemberCreationType_Secondary_BetweenPoints
                            Debug.Print swElement.GetFeature.Name & ": zwischen Punkten"
                        Case swStructureSystemMemberCreationType_Secondary_UpToMembers
                            Debug.Print swElement.GetFeature.Name & ": bis zu Elementen"
                    End Select
                End If
            Next j
        End If
    Next i
End Sub

Bemerkungen

Typen umwandeln: Das Objekt ist die Oberklasse der Daten für die einzelnen Erzeugungsarten. Du weist es je nach SecondaryStructuralMemberFeatureData.SecondaryMemberType einer Variablen eines dieser Typen zu: SecondaryMemberSupportPlaneFeatureData (Stützebene), SecondaryMemberBetweenPointsFeatureData (zwischen Punkten) oder SecondaryMemberUpToMembersFeatureData (bis zu Elementen).

Anlegen: Der Ablauf folgt den Bemerkungen zu StructureSystemFolder: Daten je Element mit ModelDocExtension.CreateStructureSystemMemberData und einem Wert swStructureSystemMemberCreationType_Secondary_… anlegen, Profil setzen, in den passenden Typ umwandeln, die Art-Daten füllen und die Elemente an ModelDocExtension.CreateStructureSystem übergeben. Sekundäre Elemente gehören dort ins zweite Feld, das erste darf Nothing sein. So macht es das Hilfebeispiel „Create Secondary Structure System Members“. Die VBA-Fassung steht bei SecondaryMemberBetweenPointsFeatureData.

Profilgruppen: StructureSystemFolder.GetProfileGroupFolders liefert Profilgruppen-Ordner (ProfileGroupFolder). Die Hilfebeispiele behandeln die Einträge aber als Feature und holen den Ordner erst mit Feature.GetSpecificFeature2. Das Beispiel oben folgt den Hilfebeispielen; so lief es auch in SOLIDWORKS 2024.

Eigenschaften und Methoden

Eigenschaften 1, davon 1 beschrieben

NameBeschreibung
SecondaryMemberTypeLiefert, wie ein sekundäres Tragwerk-Element erzeugt wird: an einer Stützebene, zwischen Punkten oder bis zu Elementen.

Siehe auch

Englisches Original: ISecondaryStructuralMemberFeatureData in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.