Methode · FeatureManager
InsertMirrorFeature2-Methode (FeatureManager)
Spiegelt die ausgewählten Features, Flächen, Körper oder Tragwerke an einer Ebene.
Syntax
Function InsertMirrorFeature2( _
ByVal BMirrorBody As Boolean, _
ByVal BGeometryPattern As Boolean, _
ByVal BMerge As Boolean, _
ByVal BKnit As Boolean, _
ByVal ScopeOptions As Long _
) As FeatureSet swFeat = swFeatMgr.InsertMirrorFeature2(False, False, False, False, swFeatureScope_AllBodies)Parameter
BMirrorBodyBooleanByValTrue: Körper spiegeln.False: Features oder Flächen.BGeometryPatternBooleanByVal- Nur beim Spiegeln von Features:
Truespiegelt nur die Geometrie, statt das ganze Feature neu zu lösen. BMergeBooleanByVal- Nur beim Spiegeln von Körpern:
Trueverschmilzt die gespiegelten Körper mit dem Original. BKnitBooleanByVal- Nur beim Spiegeln von Oberflächen:
Truefügt sie zusammen. ScopeOptionsLongByVal- Welche Körper betroffen sind, ein Wert aus
swFeatureScope_e, meistswFeatureScope_AllBodies(0).
Rückgabewert
Das neue Feature.
Beispiel
' Spiegelt das letzte Feature des Teils an der rechten Ebene.
' Vorbedingung: Ein Teil mit mindestens einem Körper-Feature ist geöffnet.
' Ergebnis: Ein neues Feature "Spiegeln".
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swLetztes As SldWorks.Feature
Dim swFeat As SldWorks.Feature
Dim bErfolg As Boolean
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
Set swLetztes = swModel.FeatureByPositionReverse(0)
If swLetztes Is Nothing Then Exit Sub
swModel.ClearSelection2 True
swLetztes.Select2 True, 1
bErfolg = swModel.Extension.SelectByID2("Ebene rechts", "PLANE", 0, 0, 0, True, 2, Nothing, swSelectOptionDefault)
If False = bErfolg Then bErfolg = swModel.Extension.SelectByID2("Right Plane", "PLANE", 0, 0, 0, True, 2, Nothing, swSelectOptionDefault)
If False = bErfolg Then Exit Sub
Set swFeat = swModel.FeatureManager.InsertMirrorFeature2(False, False, False, False, swFeatureScope_AllBodies)
If swFeat Is Nothing Then swApp.SendMsgToUser2 "Spiegeln fehlgeschlagen.", swMbWarning, swMbOk
End SubBemerkungen
Der Befehl zeigt keinen Dialog und verlässt sich ganz auf die Auswahl. Es gelten diese Markierungen:
- Features:
1 - Flächen:
128 - Körper:
256 - Tragwerke:
134217728 - Ebene oder ebene Fläche, an der gespiegelt wird:
2
Ist das letzte Feature eine Skizze oder ein anderes Feature ohne Körper, schlägt das Beispiel fehl. Gespiegelte Komponenten in einer Baugruppe erzeugst du über FeatureManager.CreateDefinition mit swFmMirrorComponent.
Siehe auch
Verfügbarkeit
SOLIDWORKS 2008
Englisches Original: IFeatureManager::InsertMirrorFeature2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.