SolidWorksMakroprogrammierung

Methode · Feature

GetFirstDisplayDimension-Methode (Feature)

Liefert die erste Bemaßung eines Features, oder Nothing, wenn es keine hat. Zusammen mit GetNextDisplayDimension geht ein Makro alle Bemaßungen durch.

Syntax

Function GetFirstDisplayDimension() As Object
Set swDispDim = swFeat.GetFirstDisplayDimension

Rückgabewert

Die erste DisplayDimension des Features, oder Nothing, wenn das Feature keine Bemaßungen hat.

Beispiel

' Listet Name und Wert aller Bemaßungen des im FeatureManager ausgewählten Features,
' bei einer Extrusion auch die Bemaßungen ihrer Skizze.
' Vorbedingung: In einem Teil ist im FeatureManager ein Feature angeklickt.
' Ergebnis:     Liste im Direktfenster (Strg+G im VBA-Editor).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swFeat As SldWorks.Feature
    Dim swDispDim As SldWorks.DisplayDimension
    Dim swDim As SldWorks.Dimension
    Dim vWert As Variant

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    If swModel.SelectionManager.GetSelectedObjectType3(1, -1) <> swSelBODYFEATURES Then
        swApp.SendMsgToUser2 "Bitte ein Feature wie eine Extrusion anklicken.", swMbWarning, swMbOk
        Exit Sub
    End If
    Set swFeat = swModel.SelectionManager.GetSelectedObject6(1, -1)

    Set swDispDim = swFeat.GetFirstDisplayDimension
    Do While Not swDispDim Is Nothing
        Set swDim = swDispDim.GetDimension2(0)
        vWert = swDim.GetValue3(swThisConfiguration, Empty)
        Debug.Print swDim.FullName & " = " & vWert(0)
        Set swDispDim = swFeat.GetNextDisplayDimension(swDispDim)
    Loop
End Sub

Bemerkungen

Ein Feature liefert auch die Bemaßungen seiner Unter-Features. Bei einer Extrusion kommen also die Tiefe und die Maße ihrer Skizze. Fragst du dagegen die Skizze selbst, bekommst du nur deren Bemaßungen. Das entspricht dem Doppelklick auf ein Feature im FeatureManager.

Die Reihenfolge ist nicht immer gleich, und ein zweiter Aufruf liefert vielleicht eine andere erste Bemaßung. Ein Makro sollte die Bemaßungen deshalb am Namen erkennen, nicht an der Position.

Die Bemaßungen der Features sollen vorher eingeblendet sein; dazu gibt es die Einstellung swDisplayFeatureDimensions. Die Makros aus Folge 29 und 30 setzen diese Einstellung nicht.

Kennst du den Namen schon, etwa D1, ist Feature.Parameter kürzer. Der Rückgabetyp ist Object. Deklariere die Variable trotzdem als DisplayDimension, dann hilft dir der VBA-Editor beim Schreiben.

Das Beispiel prüft die Auswahl auf swSelBODYFEATURES. Das passt für Extrusionen, Schnitte, Verrundungen und ähnliche Features. Skizzen haben einen eigenen Auswahltyp, swSelSKETCHES.

Siehe auch

In den Videos

Verfügbarkeit

SOLIDWORKS 98Plus

Englisches Original: IFeature::GetFirstDisplayDimension in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.