Methode · ExportPdfData
SetSheets-Methode (ExportPdfData)
Legt fest, welche Blätter einer Zeichnung beim PDF-Export ins PDF kommen: alle, nur das aktuelle oder bestimmte Blätter.
Syntax
Function SetSheets( _
ByVal Which As Long, _
ByVal Sheets As Variant _
) As BooleanbOk = swPdf.SetSheets(Which, Sheets)Parameter
WhichLongByValWelche Blätter exportiert werden, ein Wert aus
swExportDataSheetsToExport_e:swExportData_ExportAllSheets(1): alle BlätterswExportData_ExportCurrentSheet(2): nur das Blatt, das gerade angezeigt wirdswExportData_ExportSpecifiedSheets(3): nur die Blätter, die inSheetsstehen
SheetsVariantByVal- Ein Array mit den Namen der Blätter, zum Beispiel aus
DrawingDoc.GetSheetNames. Verwendet wird es beiswExportData_ExportSpecifiedSheets.
Rückgabewert
True, wenn die Auswahl übernommen wurde, sonst False. Bei swExportData_ExportAllSheets und swExportData_ExportCurrentSheet kam in SOLIDWORKS 2024 immer False, obwohl ExportPdfData.GetWhichSheets danach die neue Auswahl lieferte und das PDF richtig entstand. Nur bei swExportData_ExportSpecifiedSheets kam True. Prüf den Erfolg deshalb mit GetWhichSheets.
Beispiel
' Speichert nur das gerade angezeigte Blatt der aktiven Zeichnung als PDF
' in den Ordner der Zeichnung (Getriebe.SLDDRW, Blatt2 wird zu Getriebe_Blatt2.pdf).
' Vorbedingung: Eine Zeichnung ist geöffnet und wurde schon einmal gespeichert.
' Ergebnis: PDF-Datei, die sich danach im PDF-Programm öffnet.
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swDraw As SldWorks.DrawingDoc
Dim swPdf As SldWorks.ExportPdfData
Dim sPdf As String
Dim nFehler As Long
Dim nWarnungen As Long
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
If swModel.GetType <> swDocDRAWING Or swModel.GetPathName = "" Then
swApp.SendMsgToUser2 "Bitte eine gespeicherte Zeichnung öffnen.", swMbWarning, swMbOk
Exit Sub
End If
Set swDraw = swModel
Set swPdf = swApp.GetExportFileData(swExportPdfData)
swPdf.SetSheets swExportData_ExportCurrentSheet, swDraw.GetSheetNames
' Der Rückgabewert ist hier auch bei Erfolg False, deshalb die Auswahl nachlesen
If swPdf.GetWhichSheets <> swExportData_ExportCurrentSheet Then
Debug.Print "Blattauswahl nicht möglich."
Exit Sub
End If
swPdf.ViewPdfAfterSaving = True
sPdf = Left(swModel.GetPathName, InStrRev(swModel.GetPathName, ".") - 1) _
& "_" & swDraw.GetCurrentSheet.GetName & ".pdf"
If False = swModel.Extension.SaveAs3(sPdf, swSaveAsCurrentVersion, swSaveAsOptions_Silent, _
swPdf, Nothing, nFehler, nWarnungen) Then
Debug.Print "Fehler beim Speichern: " & nFehler
End If
End SubBemerkungen
Die Hilfe sagt nicht, was in Sheets stehen muss, wenn du alle Blätter oder nur das aktuelle exportierst. Auf der sicheren Seite bist du, wenn du auch dann die Blattnamen von DrawingDoc.GetSheetNames mitgibst, wie im Beispiel. Für das aktuelle Blatt ging auch Empty.
Für bestimmte Blätter erwartet SetSheets in Sheets ein Array mit Namen, auch wenn es nur ein Blatt ist:
Dim aBlatt(0) As String
aBlatt(0) = "Blatt2"
swPdf.SetSheets swExportData_ExportSpecifiedSheets, aBlattWillst du einfach alle Blätter exportieren, brauchst du SetSheets nicht: ModelDocExtension.SaveAs3 mit Nothing statt ExportPdfData-Objekt exportiert alle Blätter.
SetSheets merkt sich nur die Auswahl. Geschrieben wird das PDF erst beim Aufruf von SaveAs3, dem du das ExportPdfData-Objekt im Parameter ExportData mitgibst. Welche Auswahl gerade eingestellt ist, liefern ExportPdfData.GetWhichSheets und ExportPdfData.GetSheets.
Siehe auch
In den Videos
Verfügbarkeit
SOLIDWORKS 2007 SP01
Englisches Original: IExportPdfData::SetSheets in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.