SolidWorksMakroprogrammierung

Methode · DragOperator

Drag-Methode (DragOperator)

Führt einen Schritt des Ziehvorgangs mit einer Transformation aus, genau und mit dem Löser der Verknüpfungen.

Syntax

Function Drag( _
   ByVal PXform As Object _
) As Boolean
bOk = swDrag.Drag(swXform)

Parameter

PXformObjectByVal
Die Transformation (MathTransform) für diesen Schritt.

Rückgabewert

True, wenn der Schritt ausgeführt wurde, sonst False. False kommt meist wegen einer Kollision.

Beispiel

' swApp ist die SOLIDWORKS-Anwendung.
' swDrag ist ein DragOperator, etwa aus AssemblyDoc.GetDragOperator, mit Komponente aus AddComponent.
Dim swMathUtil As SldWorks.MathUtility
Dim swXform As SldWorks.MathTransform
Dim dDaten(15) As Double
Dim vDaten As Variant
Dim i As Long
Set swMathUtil = swApp.GetMathUtility
' Drehmatrix = Einheitsmatrix, Verschiebung 1 mm in X, Maßstab 1
dDaten(0) = 1#: dDaten(4) = 1#: dDaten(8) = 1#
dDaten(9) = 0.001
dDaten(12) = 1#
vDaten = dDaten
Set swXform = swMathUtil.CreateTransform(vDaten)
swDrag.TransformType = 0            ' nur Verschiebung
swDrag.UseAbsoluteTransform = False
If swDrag.BeginDrag Then
    For i = 1 To 10
        If False = swDrag.Drag(swXform) Then Exit For
        If swDrag.DragCorrected Then Debug.Print "Schritt " & i & " korrigiert."
    Next i
    swDrag.EndDrag
End If

Bemerkungen

Drag ist genauer als DragOperator.DragAsUI, das eher dem Ziehen mit der Maus entspricht und unter Umständen schneller zeichnet. Drag ist auch schneller als viele einzelne Aufrufe von Component2.SetTransformAndSolve3, weil der Löser wiederverwendet wird.

Ob die Transformation absolut oder relativ gilt, legst du mit DragOperator.UseAbsoluteTransform fest. Wird die gewünschte Lage nicht eingehalten und korrigiert SOLIDWORKS den Schritt, ist danach DragOperator.DragCorrected gesetzt.

Zur Kollisionserkennung widerspricht sich die Hilfe: Hier steht, dass der Befehl im Grundzustand schneller ist und bei eingeschalteter Kollisionserkennung oder eingeschaltetem dynamischem Abstand den ursprünglichen Modus verwendet. Auf der Seite von Component2.SetTransformAndSolve3 steht, dass Drag Kollisionserkennung und dynamischen Abstand nicht unterstützt.

Die Verschiebung der Transformation ist in Metern. DragOperator.DragCorrected meldet auch bei einer frei verschiebbaren Komponente ohne Verknüpfungen jeden Schritt als korrigiert.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2001Plus

Englisches Original: IDragOperator::Drag in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.