SolidWorksMakroprogrammierung

Eigenschaft · DocumentSpecification

ComponentList-Eigenschaft (DocumentSpecification)

Liest oder setzt, welche Komponenten OpenDoc7 beim selektiven Öffnen einer Baugruppe lädt.

Syntax

Property ComponentList As Variant
swSpec.ComponentList = vKomponenten

Wert

Die Komponenten, die geladen werden sollen. Im Beispiel der Hilfe ist das ein Array von Strings mit Komponentennamen in der Form Name-Instanz@Baugruppe, etwa "food bowl-1@bowl and chute". Welche anderen Formen erlaubt sind, sagt die Hilfe nicht.

Beispiel

' Öffnet eine Baugruppe selektiv und lädt nur die Komponente Welle-1.
' Vorbedingung: Die Baugruppe gibt es und enthält die Komponente Welle-1.
'               Pfad und Namen vor dem Start anpassen.
' Ergebnis:     Die Baugruppe ist geöffnet, geladen ist nur Welle-1.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swSpec As SldWorks.DocumentSpecification
    Dim swModel As SldWorks.ModelDoc2
    Dim aNamen(0) As String

    Set swApp = Application.SldWorks

    Set swSpec = swApp.GetOpenDocSpec("C:\Konstruktion\Getriebe.SLDASM")
    swSpec.DocumentType = swDocASSEMBLY
    swSpec.Silent = True

    aNamen(0) = "Welle-1@Getriebe"
    swSpec.ComponentList = aNamen
    swSpec.Selective = True

    Set swModel = swApp.OpenDoc7(swSpec)
    If swModel Is Nothing Then Debug.Print "Fehler " & swSpec.Error
End Sub

Bemerkungen

Die Liste wirkt nur zusammen mit DocumentSpecification.Selective = True.

Ist DocumentSpecification.InteractiveComponentSelection True, ignoriert SOLIDWORKS die Komponenten in dieser Liste. Der Anwender wählt sie dann selbst im Dialog.

Beim selektiven Öffnen legt SOLIDWORKS einen neuen Anzeigezustand an, in dem nur die Komponenten der Liste geladen und die übrigen unterdrückt sind.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2008

Englisches Original: IDocumentSpecification::ComponentList in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.