SolidWorksMakroprogrammierung

Objekt · SldWorks

CenterMark-Objekt

Eine Mittelpunktmarkierung oder eine Gruppe von Mittelpunktmarkierungen in einer Zeichenansicht: Art, Anzeige, Arme und Lage.

Deklaration Dim x As SldWorks.CenterMark · in der englischen .NET-Hilfe: ICenterMark

Beschreibung

CenterMark gibt Zugriff auf eine Mittelpunktmarkierung oder eine Gruppe von Mittelpunktmarkierungen in einer Zeichenansicht. Eine Gruppe ist eine lineare oder kreisförmige Anordnung. Mittelpunktmarkierungen sind heute Beschriftungen, früher waren sie Features. Beide Arten liefern ein CenterMark-Objekt.

Zugriff

Beispiel

' Gibt für jede Zeichenansicht des aktuellen Blatts Art, Drehwinkel und Arme ihrer Mittelpunktmarkierungen aus.
' Vorbedingung: Eine Zeichnung mit Mittelpunktmarkierungen ist offen.
' Ergebnis:     Die Werte stehen im Direktfenster, die Zeichnung bleibt unverändert.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swDraw As SldWorks.DrawingDoc
    Dim swView As SldWorks.View
    Dim swCenterMark As SldWorks.CenterMark
    Dim swAnn As SldWorks.Annotation
    Const PI As Double = 3.14159265358979

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocDRAWING Then Exit Sub
    Set swDraw = swModel

    Set swView = swDraw.GetFirstView                       ' zuerst das Blatt selbst
    Do While Not swView Is Nothing
        Set swCenterMark = swView.GetFirstCenterMark2
        Do While Not swCenterMark Is Nothing
            Set swAnn = swCenterMark.GetAnnotation
            If Not swAnn Is Nothing Then Debug.Print swView.GetName2 & ", " & swAnn.GetName
            If swCenterMark.Style <> swCenterMark_Single Then    ' IsGrouped ist auch bei einzelnen True
                Debug.Print "  Gruppe mit " & swCenterMark.GroupCount & " Markierungen, Art " & swCenterMark.Style
            Else
                Debug.Print "  Einzeln, Drehwinkel " & Round(swCenterMark.RotationAngle * 180 / PI, 1) & "°"
                Debug.Print "  Rechter Arm verlängert um " & swCenterMark.GetExtendedLength(0, swCenterMarkHandle_Right) * 1000 & " mm"
            End If
            Set swCenterMark = swCenterMark.GetNext
        Loop
        Set swView = swView.GetNextView
    Loop
End Sub

Bemerkungen

Beschriftung oder Feature: Mittelpunktmarkierungen sind heute Beschriftungen, früher waren sie Features. SelectionMgr.GetSelectedObjectType3 liefert swSelCENTERMARKSYMS (100) für Beschriftungen und swSelCENTERMARKS (28) für Features. Die Beschriftungen durchläufst du mit View.GetFirstCenterMark2 und CenterMark.GetNext, die Features holst du mit View.GetCenterMarkCount2 und View.GetCenterMarks. CenterMark.GetAnnotation liefert bei Features Nothing. Die Seite zu CenterMark schreibt die Konstante als swSelCENTERMARKSSYMS, in der Aufzählung swSelectType_e heißt sie swSelCENTERMARKSYMS.

Gruppen: Eine Gruppe ist eine lineare oder kreisförmige Anordnung. Bei Markierungen in einer Gruppe kannst du nur die Länge der Arme ändern. Den Bereich der Nummern beschreibt die Hilfe als 0 bis CenterMark.GroupCount, das Hilfebeispiel „Get and Set Center Mark Set“ läuft von 0 bis GroupCount - 1.

Anzeige: SOLIDWORKS zeigt Mittelpunktmarkierungen mit den Vorgaben des Dokuments. Für eigene Einstellungen setzt du CenterMark.UseDocDisplaySettings auf False und änderst ShowLines, Size und CenterLineFont.

Einheiten: Das Hilfebeispiel „List Center Marks in Drawing“ rechnet den Drehwinkel vom Bogenmaß in Grad um. Für Längen nennt die Hilfe keine Einheit. In SOLIDWORKS 2024 waren es Meter und Bogenmaß.

View.GetFirstCenterMark2 gibt es erst ab SOLIDWORKS 2025 SP01, in SOLIDWORKS 2024 bricht der Aufruf mit Laufzeitfehler 438 ab, dort nimmst du View.GetFirstCenterMark. CenterMark.IsGrouped liefert auch für einzelne Markierungen True (mit CenterMark.GroupCount 1), eine einzelne erkennst du sicher an CenterMark.Style mit swCenterMark_Single.

Eigenschaften und Methoden

Eigenschaften 10, davon 10 beschrieben

NameBeschreibung
CenterLineFontLiest oder setzt, ob die Linien der Mittelpunktmarkierung in der Linienart für Mittellinien gezeichnet werden.
ConnectionLinesLiest oder setzt, welche Verbindungslinien die Mittelpunktmarkierung zeigt.
GapLiest oder setzt die Lücke zwischen der Mittelpunktmarkierung und ihren Verlängerungslinien.
GroupCountLiefert die Zahl der Mittelpunktmarkierungen in einer Gruppe (lineare oder kreisförmige Anordnung).
IsGroupedLiefert, ob die Mittelpunktmarkierung zu einer Gruppe (lineare oder kreisförmige Anordnung) gehört.
RotationAngleLiest oder setzt den Drehwinkel der Mittelpunktmarkierung.
ShowLinesLiest oder setzt, ob die Mittelpunktmarkierung ihre Verlängerungslinien zeigt.
SizeLiest oder setzt die Länge der Linien der Mittelpunktmarkierung.
StyleLiefert die Art der Mittelpunktmarkierung: einzeln, lineare oder kreisförmige Gruppe.
UseDocDisplaySettingsLiest oder setzt, ob die Mittelpunktmarkierung die Anzeige-Vorgaben des Dokuments verwendet.

Methoden 11, davon 11 beschrieben

NameBeschreibung
AddToCenterMarkGroupFügt einer vorhandenen Gruppe von Mittelpunktmarkierungen eine Markierung für das ausgewählte Element hinzu.
GetAnnotationLiefert die Beschriftung (Annotation) der Mittelpunktmarkierung. Bei Markierungen alter Art, die Features sind, liefert sie Nothing.
GetExtendedLengthLiefert, um wie viel ein Arm der Mittelpunktmarkierung verlängert ist.
GetNextLiefert die nächste Mittelpunktmarkierung.
GetPositionLiefert X, Y und Z einer Mittelpunktmarkierung, bei einer Gruppe der Markierung mit der angegebenen Nummer.
HasDetachCenterMarkLiefert, ob die ausgewählte Gruppe von Mittelpunktmarkierungen abgelöste Markierungen enthält.
IsDeletedLiefert, ob eine Markierung in der Gruppe von Mittelpunktmarkierungen gelöscht ist.
IsDetachedLiefert, ob eine Mittelpunktmarkierung abgelöst (detached) ist.
ReattachToCenterMarkGroupHängt eine abgelöste Markierung wieder an das ausgewählte Element ihrer Gruppe.
SelectWählt die Mittelpunktmarkierung aus.
SetExtendedLengthVerlängert einen Arm der Mittelpunktmarkierung.

Siehe auch

Englisches Original: ICenterMark in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.