SolidWorksMakroprogrammierung

Methode · Body2

Operations2-Methode (Body2)

Verknüpft zwei temporäre Körper: vereinigen, abziehen oder schneiden.

Syntax

Function Operations2( _
   ByVal OperationType As Integer, _
   ByVal ToolBody As Object, _
   ByRef ErrorCode As Long _
) As Variant
vErgebnis = swTemp.Operations2(SWBODYCUT, swWerkzeug, nFehler)

Parameter

OperationTypeIntegerByVal
Ein Wert aus swBodyOperationType_e: SWBODYADD vereinigen, SWBODYCUT abziehen, SWBODYINTERSECT schneiden.
ToolBodyObjectByVal
Der Werkzeugkörper.
ErrorCodeLongByRef · Rückgabe
Gibt einen Wert aus swBodyOperationError_e zurück, swBodyOperationNoError (0) bei Erfolg.

Rückgabewert

Array mit den entstandenen Körpern.

Beispiel

Dim swMod As SldWorks.Modeler
Dim swQuader As SldWorks.Body2, swZyl As SldWorks.Body2
Dim dKasten(8) As Double, dZyl(7) As Double
Dim vErgebnis As Variant
Dim nFehler As Long
Set swMod = Application.SldWorks.GetModeler
dKasten(5) = 1: dKasten(6) = 0.05: dKasten(7) = 0.05: dKasten(8) = 0.02     ' 50 x 50 x 20 mm, Achse Z
dZyl(2) = -0.01: dZyl(5) = 1: dZyl(6) = 0.01: dZyl(7) = 0.04               ' Radius 10 mm, 40 mm lang
Set swQuader = swMod.CreateBodyFromBox3(dKasten)
Set swZyl = swMod.CreateBodyFromCyl(dZyl)
vErgebnis = swQuader.Operations2(SWBODYCUT, swZyl, nFehler)
If nFehler = swBodyOperationNoError Then Debug.Print UBound(vErgebnis) + 1 & " Körper als Ergebnis"

Bemerkungen

Beide Körper sind danach ungültig. Brauchst du sie noch, kopierst du sie vorher mit Body2.Copy2. Prüfe beide vorher mit Body2.Check3. Beim Schneiden eines Flächenkörpers mit einem Volumenkörper muss der Flächenkörper das Ziel sein. Bei einem Fehler „nicht mannigfaltig“ hilft Body2.ResetEdgeTolerances.

Arrays für den Modeler: Die Maße für Modeler.CreateBodyFromBox3 und Modeler.CreateBodyFromCyl übergibst du als Double-Array. Mit Array(...) brach das Makro in SOLIDWORKS 2024 mit Laufzeitfehler 10 ab, eine Variant-Variable mit Array(...) ergab Nothing.

Siehe auch

Verfügbarkeit

SOLIDWORKS 2001Plus

Englisches Original: IBody2::Operations2 in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.