Objekt · SldWorks
AutoBalloonOptions-Objekt
Die Einstellungen für automatische Positionsnummern einer Zeichnung: Anordnung, Form, Größe, Text und Nummerierung. Du übergibst sie an DrawingDoc.AutoBalloon5.
Beschreibung
Mit AutoBalloonOptions legst du fest, wie DrawingDoc.AutoBalloon5 Positionsnummern für die Stückliste einfügt. Der Ablauf:
- Eine oder mehrere Zeichenansichten oder Blätter auswählen.
- Mit
DrawingDoc.CreateAutoBalloonOptionsein AutoBalloonOptions erzeugen. - Seine Eigenschaften setzen.
- Das Objekt an
DrawingDoc.AutoBalloon5übergeben.
Zugriff
DrawingDoc.CreateAutoBalloonOptions: ein neues Objekt mit Einstellungen
Beispiel
' Fügt in der aktiven Zeichenansicht Positionsnummern ein: Kreise für zwei Zeichen
' unter der Ansicht, an einer magnetischen Linie, fortlaufend ab 1 nummeriert.
' Vorbedingung: Eine Zeichnung mit Stückliste ist offen, eine Zeichenansicht ist aktiv.
' Ergebnis: Positionsnummern unter der Ansicht, ihre Zahl steht im Direktfenster.
Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swDraw As SldWorks.DrawingDoc
Dim swView As SldWorks.View
Dim swOptionen As SldWorks.AutoBalloonOptions
Dim vNummern As Variant
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
If swModel.GetType <> swDocDRAWING Then Exit Sub
Set swDraw = swModel
Set swView = swDraw.ActiveDrawingView
If swView Is Nothing Then Exit Sub
' nicht "If Not ...": SelectByID2 liefert True als 1, und Not 1 ist in VBA nicht False
If False = swModel.Extension.SelectByID2(swView.GetName2, "DRAWINGVIEW", 0, 0, 0, False, 0, Nothing, swSelectOptionDefault) Then Exit Sub
Set swOptionen = swDraw.CreateAutoBalloonOptions
swOptionen.Layout = swDetailingBalloonLayout_Bottom ' unter der Ansicht
swOptionen.InsertMagneticLine = True
swOptionen.Style = swBS_Circular
swOptionen.Size = swBF_2Chars
swOptionen.UpperTextContent = swBalloonTextItemNumber
swOptionen.IgnoreMultiple = True ' je Position nur eine Nummer
swOptionen.ItemOrder = swBalloonItemNumbers_OrderSequentially
swOptionen.ItemNumberStart = 1
swOptionen.ItemNumberIncrement = 1
vNummern = swDraw.AutoBalloon5(swOptionen)
If IsArray(vNummern) Then Debug.Print UBound(vNummern) + 1 & " Positionsnummern eingefügt"
End SubBemerkungen
Vorgabe des Dokuments: Bei Layout, Style, Size, UpperTextContent und LowerTextContent heißt -1: die Vorgabe des Dokuments. Die Vorgaben stehen in den Dokumenteigenschaften swDetailingAutoBalloonLayout, swDetailingBOMBalloonStyle, swDetailingBOMBalloonFit, swDetailingBOMUpperText und swDetailingBOMLowerText (swUserPreferenceIntegerValue_e).
Abhängigkeiten: Einige Eigenschaften gelten nur zusammen mit einer anderen:
- CustomSize nur bei Size =
swBF_UserDef - LowerText und LowerTextContent nur bei Style =
swBS_SplitCirc - InsertMagneticLine nicht bei Layout =
swDetailingBalloonLayout_Circle - ReverseDirection nur bei ItemOrder =
swBalloonItemNumbers_OrderSequentially - EditBalloonOption nur bei EditBalloons =
True
Werte eines neuen Objekts: Welche Werte ein neu erzeugtes Objekt hat, sagt die Hilfe nicht. Setz deshalb alle Eigenschaften, auf die es dir ankommt.
Einzelne Positionsnummern: Für einzelne und gestapelte Positionsnummern gibt es eigene Einstellungsobjekte, ModelDocExtension.CreateBalloonOptions und ModelDocExtension.CreateStackedBalloonOptions.
Getestet: Das Beispiel lief in SOLIDWORKS 2024 an einer Zeichnung einer Baugruppe aus zwei Quadern und einem Würfel mit Stückliste. Es setzte zwei Positionsnummern unter die Ansicht, eine für die zwei Quader und eine für den Würfel. Die erste Fassung prüfte die Auswahl mit If Not swModel.Extension.SelectByID2(...) und brach dort immer ab: Früh gebunden liefert SelectByID2 True als 1, und Not 1 ist in VBA wahr. Jetzt prüft das Beispiel mit If False = ....
Ein neues Objekt hatte diese Werte: Layout 1, InsertMagneticLine True, Style 1, Size 2, CustomSize 0,01016, UpperTextContent 1, LowerTextContent 2, IgnoreMultiple True, ItemOrder 4, ItemNumberStart 1, ItemNumberIncrement 1, ReverseDirection False, EditBalloons False, EditBalloonOption 1, LeaderAttachmentToFaces False, Layername, UpperText und LowerText leer, FirstItem Nothing.
Stehen in der Ansicht schon Positionsnummern und ist AutoBalloonOptions.EditBalloons False, fügt DrawingDoc.AutoBalloon5 nichts ein und liefert Empty.
Eigenschaften und Methoden
Eigenschaften 19, davon 19 beschrieben
| Name | Beschreibung |
|---|---|
| CustomSize | Liest oder setzt die eigene Größe der Positionsnummern. Sie gilt nur, wenn Size auf swBF_UserDef steht. |
| EditBalloonOption | Liest oder setzt, ob vorhandene Positionsnummern ersetzt oder neu durchnummeriert werden. Gilt nur, wenn EditBalloons True ist. |
| EditBalloons | Liest oder setzt, ob beim Einfügen die Einstellung aus EditBalloonOption für vorhandene Positionsnummern gilt. |
| FirstItem | Liest oder setzt die Komponente, die die erste Positionsnummer bekommt. |
| IgnoreMultiple | Liest oder setzt, ob eine Position, die mehrfach vorkommt, nur eine Positionsnummer bekommt. |
| InsertMagneticLine | Liest oder setzt, ob mit den Positionsnummern magnetische Linien eingefügt werden. |
| ItemNumberIncrement | Liest oder setzt die Schrittweite der Positionsnummern. |
| ItemNumberStart | Liest oder setzt die erste Positionsnummer. |
| ItemOrder | Liest oder setzt, wie die Positionen nummeriert werden: Nummern beibehalten, der Reihenfolge der Baugruppe folgen oder fortlaufend. |
| Layername | Liest oder setzt den Layer, auf dem die Positionsnummern entstehen. |
| Layout | Liest oder setzt, wie die Positionsnummern um die Zeichenansicht angeordnet werden, etwa im Rechteck oder an der Unterkante. |
| LeaderAttachmentToFaces | Liest oder setzt, ob die Bezugslinien der Positionsnummern an Flächen oder an Kanten ansetzen. |
| LowerText | Liest oder setzt den unteren Text der Positionsnummern. Er gilt nur bei der Form geteilter Kreis. |
| LowerTextContent | Liest oder setzt, was im unteren Text der Positionsnummern steht, etwa die Menge. Er gilt nur bei der Form geteilter Kreis. |
| ReverseDirection | Liest oder setzt, ob die fortlaufende Nummerierung in umgekehrter Richtung läuft. |
| Size | Liest oder setzt die Größe der Positionsnummern, etwa passend für zwei Zeichen oder benutzerdefiniert. |
| Style | Liest oder setzt die Form der Positionsnummern, etwa Kreis oder geteilter Kreis. |
| UpperText | Liest oder setzt den oberen Text der Positionsnummern. |
| UpperTextContent | Liest oder setzt, was im oberen Text der Positionsnummern steht, etwa die Positionsnummer oder die Menge. |
Siehe auch
Englisches Original: IAutoBalloonOptions in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)
Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.