SolidWorksMakroprogrammierung

Objekt · SldWorks

Attribute-Objekt

Steht für ein Attribut: eigene Daten, die ein Makro an Flächen, Kanten, Features, Körper, Komponenten oder das Dokument hängt.

Deklaration Dim x As SldWorks.Attribute · in der englischen .NET-Hilfe: IAttribute

Beschreibung

Mit einem Attribut speicherst du eigene Werte direkt im Modell, etwa Bearbeitungsangaben an einer Fläche oder eine Kennung an einem Feature. Die Werte werden mit dem Modell gespeichert und bleiben an dem Element, an dem du sie angebracht hast. Jedes Attribut erscheint als Feature im FeatureManager, sichtbar oder versteckt.

Ein Attribut entsteht immer aus einer Definition (AttributeDef). Die Definition legt die Parameter mit Namen, Typ und Vorgabewert fest. Ein Attribut ist eine Instanz davon mit eigenen Werten. Die einzelnen Werte liest und schreibst du über Parameter.

Zugriff

Beispiel

' Geht den FeatureManager samt Unterfeatures durch und gibt jedes Attribut aus und woran es hängt.
' Vorbedingung: Ein Teil oder eine Baugruppe mit Attributen ist geöffnet.
' Ergebnis:     Zeilen im Direktfenster (Strg+G).
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swFeat As SldWorks.Feature
    Dim swSub As SldWorks.Feature

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub

    Set swFeat = swModel.FirstFeature
    Do While Not swFeat Is Nothing
        Ausgeben swFeat
        Set swSub = swFeat.GetFirstSubFeature           ' Attribute an Features stehen darunter
        Do While Not swSub Is Nothing
            Ausgeben swSub
            Set swSub = swSub.GetNextSubFeature
        Loop
        Set swFeat = swFeat.GetNextFeature
    Loop
End Sub

' Gibt ein Attribut-Feature mit seinem Besitzer aus, andere Features übergeht sie.
Sub Ausgeben(swFeat As SldWorks.Feature)
    Dim swAtt As SldWorks.Attribute
    Dim sWo As String

    If swFeat.GetTypeName2 <> "Attribute" Then Exit Sub
    Set swAtt = swFeat.GetSpecificFeature2
    If Not swAtt.GetEntity Is Nothing Then
        sWo = "an einem Element"
    ElseIf Not swAtt.GetBody Is Nothing Then
        sWo = "an einem Körper"
    ElseIf Not swAtt.GetComponent Is Nothing Then
        sWo = "an einer Komponente"
    Else
        sWo = "am Dokument oder an einem ungültigen Element"
    End If
    Debug.Print swAtt.GetName & ": " & sWo
End Sub

Bemerkungen

Bevor du ein Attribut anlegen oder suchen kannst, muss die Definition in der laufenden Sitzung bekannt sein. Du holst sie mit SldWorks.DefineAttribute, legst die Parameter mit AttributeDef.AddParameter an und meldest sie mit AttributeDef.Register an. Die Hilfebeispiele legen die Definition dazu jedes Mal mit demselben Namen und denselben Parametern an. Was passiert, wenn sie davon abweicht, sagt die Hilfe nicht.

Ob ein Attribut im FeatureManager zu sehen ist, legst du beim Anlegen mit AttributeDef.CreateInstance5 fest. Verschwindet die Fläche oder Kante eines Attributs durch eine Modelländerung oder wird sie unterdrückt, wird das Attribut ungültig. Das fragst du mit Attribute.GetEntityState ab.

Getestet: Das Beispiel lief in SOLIDWORKS 2024 an einem Quader mit Attributen an einer Fläche, am Dokument, am Körper und am Feature sowie in einer Baugruppe mit einem Attribut an einer Komponente. Ein Attribut an einem Feature steht im FeatureManager unter diesem Feature. Die erste Fassung des Beispiels ging nur die oberste Ebene durch und fand es deshalb nicht. Jetzt geht es auch die Unterfeatures durch.

Eigenschaften und Methoden

Eigenschaften 1, davon 1 beschrieben

NameBeschreibung
IncludeInLibraryFeatureLiefert oder ändert, ob ein Attribut in ein Bibliotheks-Feature übernommen wird.

Methoden 9, davon 9 beschrieben

NameBeschreibung
DeleteLöscht ein Attribut und aktualisiert auf Wunsch den FeatureManager.
GetBodyLiefert den Körper, an dem ein Attribut hängt, falls es an einem Körper hängt.
GetComponentLiefert die Komponente, an der ein Attribut hängt.
GetDefinitionLiefert die Definition (AttributeDef), aus der ein Attribut angelegt wurde.
GetEntityLiefert das Element (Fläche, Kante, Ecke, Schleife oder Feature), an dem ein Attribut hängt.
GetEntity2Liefert das Element, an dem ein Attribut ursprünglich angebracht wurde.
GetEntityStatePrüft, ob das Element eines Attributs ungültig, unterdrückt, mehrdeutig oder gelöscht ist.
GetNameLiefert den Namen eines Attributs.
GetParameterLiefert einen Parameter eines Attributs nach seinem Namen, um den Wert zu lesen oder zu ändern.

Nicht aufgeführt sind 6 C++-Varianten (Namen mit I davor, zum Beispiel IGetComponent). In VBA nimmst du immer den Befehl ohne I.

Siehe auch

Englisches Original: IAttribute in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.