SolidWorksMakroprogrammierung

Objekt · SldWorks

AppearanceSetting-Objekt

Ein Erscheinungsbild für Anzeigezustände: Farbe, Licht, Glanz, Spiegelung, Transparenz und Einstellungen fürs Rendern.

Deklaration Dim x As SldWorks.AppearanceSetting · in der englischen .NET-Hilfe: IAppearanceSetting

Beschreibung

AppearanceSetting gibt Zugriff auf die Darstellungseigenschaften, also das Erscheinungsbild, etwa einer Komponente in bestimmten Anzeigezuständen. Du setzt die Werte im Objekt und weist es dann mit ModelDocExtension.DisplayStateSpecMaterialPropertyValues den Komponenten und Anzeigezuständen zu, die ein DisplayStateSetting festlegt. Mit demselben Befehl liest du die aktuellen Erscheinungsbilder.

Zugriff

Beispiel

' Färbt die ausgewählte Komponente im aktiven Anzeigezustand grau, auf Ebene der Baugruppe.
' Vorbedingung: Eine Baugruppe ist offen, eine Komponente ist ausgewählt.
' Ergebnis:     Die Komponente erscheint grau.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swExt As SldWorks.ModelDocExtension
    Dim swSelMgr As SldWorks.SelectionMgr
    Dim swDSS As SldWorks.DisplayStateSetting
    Dim swAS As SldWorks.AppearanceSetting
    Dim aKomp(0) As SldWorks.Component2
    Dim aNamen(0) As String
    Dim aNeu(0) As Object
    Dim vAlt As Variant

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocASSEMBLY Then Exit Sub
    Set swExt = swModel.Extension
    Set swSelMgr = swModel.SelectionManager
    If swSelMgr.GetSelectedObjectType3(1, -1) <> swSelCOMPONENTS Then Exit Sub
    Set aKomp(0) = swSelMgr.GetSelectedObject6(1, -1)

    ' Welche Komponenten in welchen Anzeigezuständen: hier der aktive (erster Name der Liste)
    Set swDSS = swExt.GetDisplayStateSetting(swThisDisplayState)
    swDSS.Entities = aKomp
    aNamen(0) = swModel.ConfigurationManager.ActiveConfiguration.GetDisplayStates()(0)
    swDSS.Names = aNamen
    swDSS.Option = swThisDisplayState
    swDSS.PartLevel = False

    ' Aktuelles Erscheinungsbild holen, ändern und zurückgeben
    vAlt = swExt.DisplayStateSpecMaterialPropertyValues(swDSS)
    Set swAS = vAlt(0)
    swAS.Color = RGB(128, 128, 128)
    swAS.Diffuse = 0.8
    Set aNeu(0) = swAS
    swExt.DisplayStateSpecMaterialPropertyValues(swDSS) = aNeu
End Sub

Bemerkungen

Ablauf: Du setzt eine oder mehrere Eigenschaften und holst mit ModelDocExtension.GetDisplayStateSetting ein DisplayStateSetting. Darin legst du mit DisplayStateSetting.Names die Anzeigezustände fest, mit DisplayStateSetting.Entities die Komponenten und mit DisplayStateSetting.Option den Bereich. Dann liest oder setzt du die Erscheinungsbilder mit ModelDocExtension.DisplayStateSpecMaterialPropertyValues. Das Beispiel folgt dem Hilfebeispiel „Change Color of Component in Specific Display State“.

Ebene: Mit DisplayStateSetting.PartLevel = False färbt das Hilfebeispiel auf Ebene der Baugruppe. Diese Farbe setzt sich dort gegen die Farbe im Teil durch. Mit True ändert es die Farbe im Anzeigezustand des Teils, die dann nicht die bestimmende Ebene ist.

Wertebereiche: Diffuse, Luminous, Reflection, Specular, SpecularSpread und Transparent gehen von 0 bis 1. Für Transparent nennt die Hilfe 0 bis 100, wirksam sind 0 bis 1 (AppearanceSetting.Transparent). Glanzwerte gelten nur zusammen (siehe AppearanceSetting.Specular).

Rückgabewerte: Nach dem Beispiel ist die Komponente grau, Color liefert 8421504, Diffuse 0.8. Hat die Komponente im Anzeigezustand noch kein eigenes Erscheinungsbild, liefern alle Zahlenwerte -1. Die Werte von 0 bis 1 speichert SOLIDWORKS mit einfacher Genauigkeit, 0.3 kommt als 0.300000011920929 zurück.

Eigenschaften und Methoden

Eigenschaften 11, davon 11 beschrieben

NameBeschreibung
BlurryReflectionLiest oder setzt, ob Spiegelungen auf den Flächen eines Erscheinungsbilds unscharf sind.
ColorLiest oder setzt die Farbe eines Erscheinungsbilds als RGB-Wert.
DiffuseLiest oder setzt, wie stark Licht auf den Flächen eines Erscheinungsbilds wirkt (diffus), von 0 bis 1.
DoubleSidedLiest oder setzt, ob Flächen beim Rendern mit einem Raytracing-Renderer von beiden Seiten schattiert werden.
LuminousLiest oder setzt, wie hell die Flächen eines Erscheinungsbilds selbst leuchten, von 0 bis 1.
ReflectionLiest oder setzt, wie stark die Flächen eines Erscheinungsbilds spiegeln, von 0 (gar nicht) bis 1 (wie ein Spiegel).
RoundSharpEdgesLiest oder setzt, um wie viel scharfe Kanten beim Rendern mit einem Raytracing-Renderer abgerundet erscheinen. Die Geometrie bleibt gleich.
SpecularLiest oder setzt, wie stark Glanzlichter auf den Flächen eines Erscheinungsbilds sind, von 0 bis 1.
SpecularColorLiest oder setzt die Farbe der Glanzlichter eines Erscheinungsbilds als RGB-Wert.
SpecularSpreadLiest oder setzt, wie verschwommen Spiegelungen und Glanzlichter auf den Flächen eines Erscheinungsbilds sind, von 0 bis 1.
TransparentLiest oder setzt, wie durchsichtig die Flächen eines Erscheinungsbilds sind, von 0 (undurchsichtig) bis 1 (ganz durchsichtig).

Siehe auch

Englisches Original: IAppearanceSetting in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.