SolidWorksMakroprogrammierung

Eigenschaft · Annotation

Visible-Eigenschaft (Annotation)

Liest oder setzt, ob eine Beschriftung einzeln ein- oder ausgeblendet ist.

Syntax

Property Visible As Long
swAnn.Visible = swAnnotationHidden

Wert

Ein Wert aus swAnnotationVisibilityState_e:

  • swAnnotationVisible (1): eingeblendet
  • swAnnotationHidden (3): ausgeblendet
  • swAnnotationHalfHidden (2): halb ausgeblendet, siehe Bemerkungen
  • swAnnotationVisibilityUnknown (0): unbekannt

Beispiel

' Blendet alle einzeln ausgeblendeten Beschriftungen der aktiven Zeichenansicht wieder ein.
' Vorbedingung: Eine Zeichnung ist geöffnet, eine Zeichenansicht ist aktiv.
' Ergebnis:     Die Beschriftungen sind sichtbar, die Anzahl steht im Direktfenster.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swDraw As SldWorks.DrawingDoc
    Dim swView As SldWorks.View
    Dim swAnn As SldWorks.Annotation
    Dim nAnzahl As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocDRAWING Then Exit Sub
    Set swDraw = swModel
    Set swView = swDraw.ActiveDrawingView
    If swView Is Nothing Then Exit Sub

    Set swAnn = swView.GetFirstAnnotation3
    Do While Not swAnn Is Nothing
        If swAnn.Visible = swAnnotationHidden Then
            swAnn.Visible = swAnnotationVisible
            nAnzahl = nAnzahl + 1
        End If
        Set swAnn = swAnn.GetNext3
    Loop
    swModel.ActiveView.GraphicsRedraw Empty
    Debug.Print nAnzahl & " Beschriftungen eingeblendet."
End Sub

Bemerkungen

Was die Eigenschaft erfasst: Sie sagt nur, ob die Beschriftung einzeln ausgeblendet wurde, oder die Bemaßungen eines Features gesammelt. Ob sie auf einem ausgeblendeten Layer liegt oder ihr Feature unterdrückt ist, erfasst sie nicht. „Eingeblendet“ heißt also nicht unbedingt, dass die Beschriftung auf dem Bildschirm zu sehen ist.

Halb ausgeblendet: swAnnotationHalfHidden ist kein dauerhafter Zustand. Beim Befehl „Beschriftungen aus-/einblenden“ einer Zeichnung erscheinen solche Beschriftungen grau, wenn alle gezeigt werden, und sind danach wieder ausgeblendet.

Neu zeichnen: Nach einer Änderung zeichnest du den Grafikbereich neu, damit sie zu sehen ist. Die Hilfe nennt dafür das veraltete ModelDoc2.GraphicsRedraw2, heute nimmst du ModelView.GraphicsRedraw wie im Beispiel.

Siehe auch

Verfügbarkeit

SOLIDWORKS 99 SP05

Englisches Original: IAnnotation::Visible in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.