SolidWorksMakroprogrammierung

Eigenschaft · Annotation

Color-Eigenschaft (Annotation)

Liest oder setzt die Farbe einer Beschriftung in einer Zeichnung, abweichend von der Farbe des Layers.

Syntax

Property Color As Long
swAnn.Color = RGB(255, 0, 0)

Wert

Die Farbe als COLORREF-Wert. In VBA bildest du ihn mit RGB(Rot, Grün, Blau).

Beispiel

' Färbt alle Beschriftungen der aktiven Zeichenansicht rot.
' Vorbedingung: Eine Zeichnung ist geöffnet, eine Zeichenansicht ist aktiv.
' Ergebnis:     Die Beschriftungen der Ansicht sind rot.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swDraw As SldWorks.DrawingDoc
    Dim swView As SldWorks.View
    Dim swAnn As SldWorks.Annotation

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocDRAWING Then Exit Sub
    Set swDraw = swModel
    Set swView = swDraw.ActiveDrawingView
    If swView Is Nothing Then Exit Sub

    Set swAnn = swView.GetFirstAnnotation3
    Do While Not swAnn Is Nothing
        swAnn.Color = RGB(255, 0, 0)
        Set swAnn = swAnn.GetNext3
    Loop
    swModel.ActiveView.GraphicsRedraw Empty
End Sub

Bemerkungen

Farben für Beschriftungen gibt es nur in Zeichnungen. Liegt die Beschriftung auf einem Layer, überschreibt die Farbe die des Layers. Ob die Beschriftung die Farbe des Layers benutzt, liefert Annotation.LayerOverride. Dort setzt du sie auch wieder auf die Farbe des Layers zurück.

Nach dem Setzen liefert Annotation.LayerOverride swLayerOverrideColor. Kommt die Beschriftung danach auf einen Layer, behält sie ihre eigene Farbe.

Siehe auch

Verfügbarkeit

SOLIDWORKS 99

Englisches Original: IAnnotation::Color in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.