SolidWorksMakroprogrammierung

Objekt · SldWorks

AdvancedSelectionCriteria-Objekt

Die erweiterte Komponentenauswahl einer Baugruppe: Kriterien anlegen, als Abfrage laden oder speichern und die passenden Komponenten auswählen.

Deklaration Dim x As SldWorks.AdvancedSelectionCriteria · in der englischen .NET-Hilfe: IAdvancedSelectionCriteria

Beschreibung

AdvancedSelectionCriteria steht für den Dialog der erweiterten Komponentenauswahl (Standard-Symbolleiste, Advanced Select). Du legst eine Liste von Kriterien an, etwa „benutzerdefinierte Eigenschaft Lieferant = Extern“, und wählst dann alle Komponenten aus, die sie erfüllen. Die Liste kannst du als Abfragedatei speichern und wieder laden. Was davon in SOLIDWORKS 2024 klappt, steht in den Bemerkungen.

Zugriff

Beispiel

' Wählt alle Komponenten aus, deren benutzerdefinierte Eigenschaft "Lieferant" den Wert "Extern" hat.
' Vorbedingung: Eine Baugruppe ist offen.
' Ergebnis:     Die passenden Komponenten sind ausgewählt, ihre Zahl steht im Direktfenster.
Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swAssy As SldWorks.AssemblyDoc
    Dim swKrit As SldWorks.AdvancedSelectionCriteria
    Dim i As Long

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then Exit Sub
    If swModel.GetType <> swDocASSEMBLY Then Exit Sub
    Set swAssy = swModel
    swModel.ClearSelection2 True

    Set swKrit = swAssy.GetAdvancedSelection
    For i = swKrit.GetItemCount - 1 To 0 Step -1        ' Kriterien vom letzten Mal entfernen
        swKrit.DeleteItem i
    Next i

    ' Kategorienamen wie in den Hilfebeispielen (siehe Bemerkungen)
    swKrit.AddItem2 "Custom Property", "Lieferant", swAdvSelectType_Equals, "Extern", True
    If swKrit.Select Then
        Debug.Print swModel.SelectionManager.GetSelectedObjectCount2(-1) & " Komponenten ausgewählt"
    Else
        Debug.Print "Keine passende Komponente."
    End If
End Sub

Bemerkungen

Kategorien und Bedingungen: Welche Kategorien, Bedingungen und Werte es gibt, steht in der SOLIDWORKS-Hilfe unter „Assemblies > Basic Component Operations > Selecting Components > Advanced Component Selection“. Die Bedingung übergibst du als Wert aus swAdvSelectType_e, in der Abfragedatei steht sie als Zeichen wie =. Die Hilfebeispiele nennen die Kategorien englisch, etwa Custom Property oder In Context Relations. Ob eine deutsche SOLIDWORKS-Installation deutsche Namen erwartet, sagt die Hilfe nicht.

In SOLIDWORKS 2024 mit deutscher Oberfläche wählt das Beispiel die Komponenten mit „Lieferant = Extern“ aus. Bei benutzerdefinierten Eigenschaften war die erste Kategorie egal. "Custom Property", "Benutzerdefinierte Eigenschaft" und sogar "Quatsch" wählten dasselbe aus. Es zählten nur die zweite Kategorie (der Name der Eigenschaft), die Bedingung und der Wert. Mit "SW Special" und "Document name" wählte Select dagegen nichts aus, in keiner Reihenfolge. Die Namen der übrigen Kategorien sind also nicht geklärt.

Liste der Kriterien: In SOLIDWORKS 2024 liefert AssemblyDoc.GetAdvancedSelection bei jedem Aufruf ein neues Objekt. Die Kriterien vom letzten Mal sind darin aber noch da. Das Beispiel löscht sie darum zuerst.

Abfragedateien: AdvancedSelectionCriteria.SaveCriteria speichert seit SOLIDWORKS 2021 nur noch XML. Laden kannst du XML und ältere *.sqy-Dateien. In SOLIDWORKS 2024 schrieb SaveCriteria kein XML und ließ den Namen der Eigenschaft weg, LoadCriteria las die Datei mit 0 Kriterien ein (siehe dort). Eine XML-Datei, die du selbst schreibst, lädt AdvancedSelectionCriteria.LoadCriteria dagegen richtig. Ihren Aufbau zeigt die Seite LoadCriteria.

Veraltete Befehle: AdvancedSelectionCriteria.AddItem und AdvancedSelectionCriteria.GetItem kannten nur eine Kategorie. Seit SOLIDWORKS 2021 nimmst du AddItem2 und GetItem2.

Eigenschaften und Methoden

Methoden 9, davon 7 beschrieben, 2 veraltet

NameBeschreibung
AddItemveraltet ersetzt durch AdvancedSelectionCriteria.AddItem2
AddItem2Fügt der erweiterten Komponentenauswahl ein Kriterium hinzu, etwa „benutzerdefinierte Eigenschaft IsPeg = Yes“.
DeleteItemLöscht ein Kriterium aus der Liste der erweiterten Komponentenauswahl.
GetItemveraltet ersetzt durch AdvancedSelectionCriteria.GetItem2
GetItem2Liefert ein Kriterium der erweiterten Komponentenauswahl: Kategorien, Bedingung, Wert und UND/ODER.
GetItemCountLiefert die Zahl der Kriterien in der Liste der erweiterten Komponentenauswahl.
LoadCriteriaLädt eine Abfragedatei (XML oder ältere SQY) als aktuelle Liste der erweiterten Komponentenauswahl.
SaveCriteriaSpeichert die aktuelle Abfrage der erweiterten Komponentenauswahl in eine Datei, als XML.
SelectWählt die Komponenten der Baugruppe aus, die die aktuellen Kriterien der erweiterten Komponentenauswahl erfüllen.

Siehe auch

Englisches Original: IAdvancedSelectionCriteria in der SOLIDWORKS API-Hilfe ↗ (dort mit dem .NET-Namen)

Fragen zu diesem Befehl oder ein Befehl fehlt? Frag im Discord.